with Proc TABULATE you can not trafficligth for a column, based on values from another column.
You can do this with Proc REPORT, see sample below. Note, that when using ACROSS in Proc REPORT, you have to use special column names to address the appropriate column. The example uses an array to access the across values.
proc report data=sashelp.cars;
columns type horsepower=hpall_avg origin, horsePower=hpavg origin, invoice=invsum _dummy;
define type / group;
define origin / across;
define hpall_avg / analysis mean f=commax12.;
define hpavg / analysis mean f=commax12.;
define invsum / analysis n f=commax12.;
define _dummy / computed;
compute _dummy / char length=32;
array nhpavg{*} _c3 _c4_ _c5_;
do i = 1 to dim(nhpavg);
if nhpavg{i} > (hpall_avg * 1) then do;
call define(vname(nhpavg{i}), "style", "style={background=cx4dbf81}");
end;
end;
endcomp;
run;
... View more
Are you looking for something like this?
data plotdata;
infile cards dlm=",";
input
id group $ x y
;
if group = "A" then do;
ya = y;
end;
if group = "B" then do;
yb = y;
end;
cards;
1,A,10,2
1,A,30,10
1,B,110,400
1,B,140,150
2,B,110,750
2,A,20,11
2,B,150,600
2,A,70,7
3,A,100,16
3,A,75,8
3,B,120,800
3,B,130,1200
;
proc sort data=plotdata;
by x group id ;
run;
proc sgplot data=plotdata nocycleattrs;
step x=x y=ya /
justify=center group=id markers lineattrs=(pattern=solid thickness=0.8mm)
datalabel
;
step x=x y=yb /
justify=center group=id markers lineattrs=(pattern=solid thickness=0.8mm)
datalabel
y2axis
;
... View more
hi Joel
Thanks for the tip, helped me find the right information for coordinates used in Switzerland. Should have have this tip a year ago;-)
Here are some websites with additional information:
https://epsg.io/ and http://spatialreference.org/
So for Switzerland I have found https://epsg.io/21781 or in GPROJECT from="EPSG:21781"
... View more
I suggest to use a Stored Process.
You can use the %MDSECDS() macro to get a list of all the reports like this:
%mdsecds(
folder="/Shared Data"
, includesubfolders=YES
,membertypes="Report.BI"
)
You then get a data set WORK.MDSECDS_OBJS with all the objects. with this you can build the link to call your report.
Using the Stored Process will take the permission of the individual user into account.
... View more
Run your code with the DEBUG= option, see below
proc soap
in=request
out=response
url="https://swea.riksbank.se:443/sweaWS/services/SweaWebServiceHttpSoap12Endpoint"
debug="c:\temp\soap.txt"
;
run;
According to the doc you also need tp specify some options to make the HTTPS protocol work, see here
http://documentation.sas.com/?cdcId=pgmmvacdc&cdcVersion=9.4&docsetId=proc&docsetTarget=n0ugstrmu2wfrqn1dinivtz4cwh8.htm&locale=en
... View more
You have to convert one of the variables, so that both have the same type.
See http://support.sas.com/kb/24/590.html and https://blogs.sas.com/content/sgf/2017/03/28/changing-variable-type-and-variable-length-in-sas-datasets/
Also check the programs that created the two datasets, maybe you can already change it there.
... View more
If your file looks like this, then there should be no problem in read it.
See this sample
filename xmlsrc temp;
data _null_;
infile cards;
input;
file xmlsrc;
put _infile_;
cards4;
<?xml version="1.0"?>
<EMSDataSet>
<Record>
<inc_disposition>
<DispositionID>000000</DispositionID>
<IncidentID>000000</IncidentID>
<PatientDisposition>012012</PatientDisposition>
<Base_Hospital_Contacted>0000</Base_Hospital_Contacted>
</inc_disposition>
</Record>
</EMSDataSet>
;;;;
filename xmlmap temp;
libname xmlin xmlv2 xmlfileref=xmlsrc xmlmap=xmlmap automap=replace;
proc copy in=xmlin out=work;
run;
See also this post, where the XML Mapper is used with XML parsing validation set to minimal
https://communities.sas.com/t5/SAS-Procedures/Error-while-generating-XML-Map-in-XML-Mapper/td-p/173376
... View more
Please provide the commands you have tried. The ExportPackage has an option to specify a name pattern you may also explicitly specify the object your interested in.
Here is an example using the -name option
ExportPackage.exe -profile <yourProfile> -package "c:\temp\test.spk" -objects "/shared data/stp_samples" -includeEmptyFolders -name display -nameMatchType STARTSWITH
... View more
To see what is in your file I suggest to use the following code:
data _null_;
infile "<yourFile>" obs=10;
input;
list;
run;
If the input record contains non printable chars then you will get the input record also displayed in hex. So you will see the delimiter between data values. Maybe it is x09 for a tab character.
... View more
You can change the order of the across and analysis variable in the COLUMN statement to achieve something similar. This allows you to have a common heading and suppress one heading using an empty label.
Have a look at the sample below.
/*
* default layout
*/
proc report data=sashelp.cars;
column type origin, invoice;
define type / group;
define origin / across;
define invoice / analysis mean;
run;
/*
* analysis before across var
*/
proc report data=sashelp.cars;
column type invoice, origin;
define type / group;
define origin / across " ";
define invoice / analysis mean "Invoice mean";
run;
... View more
Noticed, that you have a time zone offset in your datetime value.
Have a look at the doc, Reading Dates and Times By Using the ISO 860 Basic and Extended Notations there are specific informats that will make use of the time zone offset information.
Here is an example:
data demo;
have='2017-12-01T12:43:28-05:00';
dt1 = input(have, anydtdtm.);
dt2 = input(have, E8601DZ.);
format dt: datetime19.;
run;
proc print data=demo;
run;
... View more
Just run the code sample provided without any macro around it, do you get the desired result?
Maybe your macro is resetting the TITLE definition.
Also provide the answers to the three questions above.
... View more
Use a drop-down list control using the "year" category, add a parameter to contain the selected year.
Then use this parameter in the filter of the three bar charts to filter on the selectedYear, selectedYear -1, etc.
Make the year a calculated numeric data item, this will work with VA7.3 and VA7.4
... View more
