BrunoMueller Tracker

How to customize your Programming Run-Time Servers pod names

BrunoMueller — Mon, 20 Jul 2026 07:19:07 GMT

As a SAS Viya administrator you may want to identify different workloads based on the different launcher contexts that you have defined. Currently, by default, all Programming Run-Time Servers pods will have the same, based on the type, prefix for pod names and there is no way to differentiate them from looking at the pod names.

For instance if you use a compute server either by using SAS® Data and AI Studio, SAS Enterprise Guide or the SAS extension for Visual Studio Code the pods are all named using the same prefix. What if you wanted to name them differently, so you could easily distinguish them. The same holds true for batch and connect servers. This article will show you how you can change the prefix being used.

Re: sas-viya batch jobs, file sets and the SAS administrator

BrunoMueller — Mon, 20 Jul 2026 06:36:41 GMT

Yes the SAS Administrators group has rules that allow them to do most of the things.

Re: to retrieve both path and program name in batch viya

BrunoMueller — Thu, 16 Jul 2026 10:28:15 GMT

Please clarify how the program is submitted for batch processing. Are you using the sas-viya batch jobs CLI or are you doing a "background submit" in SAS Studio?

Where is the code stored you used in the sas-viya batch jobs submit-pgm?

Here some examples when using the sas-viya batch jobs CLI.

Have a look at these macro variables: SYSPROCESSMODE, SYSPROCESSNAME

AUTOMATIC SYSPROCESSMODE SAS Batch Mode
AUTOMATIC SYSPROCESSNAME Program /gelcontent/gelcorp/launcher-info.sas

This is an example where the program is stored on the SAS server. The batch program was started using this command:

sas-viya batch jobs submit-pgm --rempgm /gelcontent/gelcorp/launcher-info.sas -c default

If the code is stored somewhere accessible by the sas-viya command and the batch job is started as

sas-viya batch jobs submit-pgm --pgm launcher-info.sas -c default

The macro variables look like this, the program is uploaded and stored in the fileset

AUTOMATIC SYSPROCESSMODE SAS Batch Mode
AUTOMATIC SYSPROCESSNAME Program /opt/sas/viya/config/var/run/batch/default/uid2002/JOB_20260716_101153_102_1/launcher-info.sas

What is it you want to achieve?

See this article https://communities.sas.com/t5/SAS-Communities-Library/sas-viya-batch-jobs-file-sets-and-the-SAS-administrator/tac-p/990918 for some more details on filesets.

Re: sas-viya batch jobs, file sets and the SAS administrator

BrunoMueller — Thu, 16 Jul 2026 07:15:50 GMT

The ability to create batch jobs is controlled by this rule: Uri: /batch/jobs Permission: create

So instead of principal "Authenticated Users" you could change it to a group of your choosing.

You can disable the original rule. Make a copy of the original and set the principal. So it is easy to go back to the original setting.

If a user not authorized tries to submit a batch job the following error is produced:

sas-viya -p eric batch jobs submit-pgm --pgm launcher-info.sas -c batch2
>>> The file set "JOB_20260716_065351_984_1" was created.
>>>   Uploading "launcher-info.sas".
Failed to start the job.
  Forbidden

Re: Get connection information for a SAS9 server in Enterprise Guide and use it in VS Code

BrunoMueller — Thu, 14 May 2026 18:50:22 GMT

@yabwon glad you found it helpful. Too bad it came to late for you. BTW, just recently I watched your SASinnovate presentation on SAS packages. Thanks for that.

Get connection information for a SAS9 server in Enterprise Guide and use it in VS Code

BrunoMueller — Wed, 13 May 2026 05:40:36 GMT

The other day someone asked me how can I connect from the SAS extension in VS Code to the same workspace servers I can see in Enterprise Guide. Using the information from the profile used in Enterprise Guide did not work. So it seems those two applications work slightly different.

This post will provide a step by step guide how to lookup the information in Enterprise Guide and use it when defining a new connection in the SAS extension for VS Code.

Re: Programmatically finding a user's own repository in the SAS metadata repository

BrunoMueller — Tue, 05 May 2026 17:36:38 GMT

Find below some general code to list all project repositories and their owner.

data md_project_repo_owner;
  length
    nRep 8
    type etype $ 32
    id eId $ 32
    repSearch $ 128
    repURI $ 128
    repName $ 128
    repPath $ 1024
    extSearch $ 1024
    ownerURI $ 128
    ownerId $ 64
  ;
  call missing(type, etype, id, eid, repSearch, repURI, repName, repPath, extSearch, ownerURI);


  * 
  * search for Project repositories
  *;
  repSearch = "OMSOBJ:Repository?@RepositoryType = 'Project'";
  nRep = metadata_resolve(repSearch, type, id);
  putlog "NOTE: Number of Objects found for" +1 repSearch= nRep=;

  *
  * get the individual repURI for each entry
  *;
  do objN = 1 to nRep;
    rc = metadata_getnobj(repSearch, objN, repURI);
    *
    * get Object type and id from objURI
    *;
    eObjType = scan(repURI, 2, ":\");
    eObjId = scan(repURI, 2, "\");

    *
    * get repository details
    * more attributes are available
    *;
    rc = metadata_getattr(repURI, "Name", repName);
    rc = metadata_getattr(repURI, "Path", repPath);

    *
    * search Extension objects
    *;
    extSearch = cats("OMSOBJ:Extension?@Name='ProjectRepository' and @Value=", quote(strip(eObjId), "'"));
    nExt = metadata_resolve(extSearch, etype, eid);

    *
    * get the owner object
    *;
    rc = metadata_getnasn(eId, "OwningObject", 1, ownerURI);

    *
    * get owner id
    *;
    rc = metadata_getattr(ownerURI, "Name", ownerId); 
    output;
  end;
  keep repURI repName repPath ownerURI ownerId;
run;

Who’s been using my CAS tables? Now with activity records

BrunoMueller — Mon, 04 May 2026 09:19:07 GMT

You might remember my post on Who's been using my CAS tables? where I wrote about the audit entries being created for access to CAS tables and how to read them. Recently I read in the documentation for Upcoming Critical Changes for SAS® Viya® Platform the section on Recording Audit Entries Disabled at Stable 2026.05. Does this mean, this information is no longer available?

Do not worry, we still have the same CAS access information available. We just need to read them using a different command. This article will provide the details needed to continue using these audit information.

Get the Code From a SAS Studio Flow using pure SAS program code

BrunoMueller — Mon, 04 May 2026 09:06:59 GMT

Sometimes we want to get the code that is behind a SAS Studio flow. See this post How To Get the Code From a SAS Studio Flow and Why It Matters for more details. The post provides a SAS program to read the generated code. Now often not all the code will fit into the max length of character variable in a SAS data set.

Help me type, the sas-viya CLI supports auto-complete

BrunoMueller — Tue, 21 Apr 2026 11:23:32 GMT

In a Linux terminal we are used to auto-complete for commands, filenames and so on. However when using the sas-viya command-line interface (CLI), pressing the tab key would do nothing. Of course you do have the built-in help, but it is not the same experience.

Beginning with Stable 2026.02 the sas-viya CLI now supports auto-completion for plugins and commands. This article will introduce you how to enable this feature and how to use it.

Re: How to change the format in VA in a 100% stacked bar chart

BrunoMueller — Tue, 21 Apr 2026 06:52:07 GMT

You are welcome and thanks for the feedback.

Re: Multiples box plots

BrunoMueller — Mon, 02 Mar 2026 07:42:01 GMT

About title and footnote. See sample program below. Depending on where the title and footnote statements are used, the apply to the whole page, or just within the region.

ods _all_ close;

ods graphics / reset=all height=110mm width=160mm outputfmt=png;

ods pdf file="%sysfunc(pathname(work))/layout.pdf" startpage=never;

title "Title outside of layout";
footnote "Footnote outside of layout";

ods layout gridded columns=1;
ods region;
title "Title inside region 1";
footnote "Footnote inside region 1";
proc sgplot data=sashelp.cars;
vbar type / group=origin response=invoice stat=mean;
run;
ods region;
title;
footnote;
proc sgplot data=sashelp.cars;
vbar type / group=origin response=invoice stat=mean;
run;
ods layout end;

ods pdf startpage=now;

title "Title outside of layout";
footnote "Footnote outside of layout";

ods layout gridded columns=1;
ods region;
title "Title for table";
footnote "Footnote for table";
proc print data=sashelp.class(obs=10);
run;

ods layout end;
ods pdf close;

Re: Multiples box plots

BrunoMueller — Thu, 26 Feb 2026 15:02:11 GMT

As long as two rows of images will fit on the page you just continue with

ods region;
proc sgplot ...;

for the next 4 plots.

Re: Multiples box plots

BrunoMueller — Thu, 26 Feb 2026 13:26:59 GMT

Since you output to a PDF, you can set some options like papersize and margins. You could use a A3 papersize, so there is more space for the graph, but still print it as A4. I would set the height and width using mm, as you can measure on the paper with a ruler. ODS LAYOUT has support for COLUMN_GUTTER=dimension and ROW_GUTTER=dimension

Here is a sample to test things out. I used macros for some of the options to make it easier to change

ods _all_ close;
options
  papersize="A3"
  topmargin=1cm
  bottommargin=1cm
  leftmargin=1cm
  rightmargin=1cm
  orientation=landscape
  nodate nonumber;
;
ods graphics / reset=all width=90mm height=135mm outputfmt=png;
ods pdf file="%sysfunc(pathname(work))/layout_gridded.pdf";
ods layout gridded columns=4 column_gutter=0;

%macro dataLabel;
  datalabel=model 
    labelfar
%mend;

%macro displayStats;
  displaystats=(n mean median max datamax min datamin  iqr range std q1 q3)
%mend;

%macro datalabelAttrs;
  datalabelattrs=(size=6pt color=blue Style=Normal Weight=Normal) boxwidth=1
%mend;

ods region;

  proc sgplot data=sashelp.cars;
    vbox invoice /
      %dataLabel
      %displayStats
      %dataLabelAttrs
    ;
  run;

ods region;

  proc sgplot data=sashelp.cars;
    vbox horsepower/
      %dataLabel
      %displayStats
      %dataLabelAttrs
    ;
  run;

ods region;

  proc sgplot data=sashelp.cars;
    vbox mpg_city/
      %dataLabel
      %displayStats
      %dataLabelAttrs
    ;
  run;

ods region;

  proc sgplot data=sashelp.cars;
    vbox mpg_highway/
      %dataLabel
      %displayStats
      %dataLabelAttrs
    ;
  run;

ods layout end;
ods pdf close;

The PDF produced is attached.

Re: Multiples box plots

BrunoMueller — Thu, 26 Feb 2026 08:15:29 GMT

You are not using ODS LAYOUT and you do not specify the size of the image to create, so I guess that is why you do not have them on the same page.

Re: Multiples box plots

BrunoMueller — Wed, 25 Feb 2026 12:36:27 GMT

How about using ODS LAYOUT, see sample below.

ods _all_ close;

ods graphics / width=80mm height=80mm outputfmt=static;
ods pdf file="c:\temp\layout_gridded.pdf";

ods layout gridded columns=2;

ods region;
proc sgplot data=sashelp.cars;
vbox invoice;
run;

ods region;
proc sgplot data=sashelp.cars;
vbox horsepower;
run;

ods region;
proc sgplot data=sashelp.cars;
vbox mpg_city;
run;

ods region;
proc sgplot data=sashelp.cars;
vbox mpg_highway;
run;

ods layout end;
ods pdf close;

Re: How to use the Sample: Load cas-shared-default Public data job to load SAS7BDAT files?

BrunoMueller — Mon, 09 Feb 2026 09:50:43 GMT

Please note the filter is case sensitive.

I am not aware of a way to see the actual code being used.

it will help if we see the filter definition.

A look into the future, Upcoming Critical Changes

BrunoMueller — Thu, 11 Dec 2025 12:44:47 GMT

The SAS documentation provides a "What's New" section. This will tell you about new functionality and features within the SAS software. You will see this in the doc for a Stable or Long-Term Support release when it comes out.

Being able to know what the future holds can be an advantage. For SAS Viya there is now a way to see upcoming critical changes. Having this information will allow for better planning when you think about your next SAS Viya release upgrade.

Re: PROC SGPLOT axis break with different distribution/scale before and after the break

BrunoMueller — Wed, 26 Nov 2025 13:49:03 GMT

As a start have a look here https://blogs.sas.com/content/graphicallyspeaking/2012/05/31/broken-y-axis/ it provides a code sample that does the break of an axis "manually". You will have to use the GTL (Graph Template Language). I have taken the above example and adapted it for a broken X axis. Since you did not provide any data and what kind of plot you want I assumed something.

See this sample:

data plotdata;
  do month = 1 to 14;
    value = rand("integer", 10, 20);
    output;
  end;
run;

/*-- manual break in axis --*/
proc template;
  define statgraph series_break;
    begingraph;
      /* the columweights determine the space available */
      layout lattice / columns=2 rowdatarange=union columnweights=(0.9 0.1) ;
        layout overlay / 
          xaxisopts=(
            griddisplay=on display=(ticks tickvalues label) 
            tickvalueattrs=(size=7)
             linearopts=(viewmin=1 viewmax=11 TICKVALUELIST=(1 2 3 4 5 6 7 8 9 10))
             offsetmax=0
          );
          seriesplot x=month y=value;
        endlayout;
        layout overlay / 
          xaxisopts=(
            griddisplay=on display=(ticks tickvalues) 
            tickvalueattrs=(size=7)
            linearopts=(viewmin=11 TICKVALUELIST=(11 12 13 14))
            offsetmin=0
          )
          yaxisopts=( display=none)
        ;
          seriesplot x=month y=value;
        endlayout;
      endlayout;
    endgraph;
  end;
run;

ods graphics / reset=all;

proc sgrender data=plotdata template=series_break;
run;

Re: Guidance on Visualizing Postal Code Areas in SAS Visual Analytics

BrunoMueller — Wed, 12 Nov 2025 13:46:41 GMT

It is best to start with the documentation: https://go.documentation.sas.com/doc/en/vacdc/v_035/vareportdata/p031vp9uc5y5iun0zipy3c1trkqn.htm please choose the proper version that you are using.

Basic Steps:

First you will need the corresponding polygon information for your PLZ8 regions. The easiest would be to have the data as SHP file.
The SHP file needs to be imported as a CAS table, see Loading Geographic Polygon Data as a CAS Table
Define your own Geographic Data Provider, you need to be an administrator (by default only Administrators can do this). See Create a Geography Data Item By Using Custom Polygonal Shapes, Lines, or Coordinates from a Geographic Data Provider