Hi:
If you were working in Base SAS, then, I'd recommend that you use the #1 example -- the SAS XML Libname Engine to create your XML file. Since the XML Libname Engine works with
ONE dataset in and
ONE XML file out, however, you might have to do some data manipulation ahead of time before the XML creation step.
I do not have a current copy of DI Studio to test with. But it was my understanding that the DI Studio documentation and classes did have some information on creating XML files. I thought they achieved this through DI Studio transforms.
I don't understand the XML samples you showed in the XML snippets above, you show some XML but then say it's NOT what you want? That's sort of confusing. It seems to me that you have some variables in TABLE A and some other, possibly related variables in TABLE B and you need to get those and possibly some information from TABLE C into ONE XML file????
Is what you show the kind of XML you want to get or are you trying to show that the final XML will be composed of some columns from Table A and some columns from Table B???
You might want to contact SAS Tech Support for more immediate help, especially if DI Studio is involved, because they can help you with the DI Studio piece of your question.
For information purposes, I'm showing how you can use information from 2 tables to make 1 XML file using the XML libname engine. If you wanted to generate different XML tags than what you get by default, then you'd have to write your own custom tagset template. Again, I believe that DI Studio has some built in mechanisms for dealing with XML -- especially CDISC related XML -- but you'd have to look at the DI Studio doc or work with Tech Support.
cynthia
In the example program below, I have 3 variables coming from TABLEA and 2 variables coming from TABLEB. I merge the 2 files together and rename the variables so that the new names are used in the XML file.
Program:
[pre]
data tableA;
infile datalines;
input char $ color $ about $;
return;
datalines;
bigbird yellow happy
kermit green happy
oscar green grouch
;
run;
data tableB;
length show1 show2 $30;
infile datalines dsd;
input char $ show1 $ show2 $;
return;
datalines;
bigbird,"Sesame Street","Big Bird in China"
kermit,"Sesame Street", "Muppet Show"
oscar,"Sesame Street","Follow That Bird"
;
run;
libname xmlout xml "c:\temp\both.xml";
data xmlout.muppet (rename=(char=column1 color=column2 about=column3
show1=column4 show2=column5));
merge tableA(in=ina) tableB(in=inb);
by char;
if ina and inb;
run;
libname xmlout clear;
[/pre]
XML output file:
[pre]
<?xml version="1.0" encoding="windows-1252" ?>
<TABLE>
<MUPPET>
<column1> bigbird </column1>
<column2> yellow </column2>
<column3> happy </column3>
<column4> Sesame Street </column4>
<column5> Big Bird in China </column5>
</MUPPET>
<MUPPET>
<column1> kermit </column1>
<column2> green </column2>
<column3> happy </column3>
<column4> Sesame Street </column4>
<column5> Muppet Show </column5>
</MUPPET>
<MUPPET>
<column1> oscar </column1>
<column2> green </column2>
<column3> grouch </column3>
<column4> Sesame Street </column4>
<column5> Follow That Bird </column5>
</MUPPET>
</TABLE>
[/pre]
