How to use a macro variable in a if else condition

[alepage]

The script below is not giving the expected result.

Please correct the script

/*%let cie=b2;*/
%let cie=b2;

data class;
format company $1.;
set sashelp.class;
if &cie eq b1 then company="A";
else if &cie eq b2 then company ="B";
run;

[Kathryn_SAS]

There are no variables named b1 or b2 in the sashelp.class data set. What are you expecting this step to do?

[Kathryn_SAS]

If you are expecting this to be treated as a string, then try:

%let cie=b2;

data class;
format company $1.;
set sashelp.class;
if "&cie" eq "b1" then company="A";
else if "&cie" eq "b2" then company ="B";
run;

[alepage]

this script is not working.

[PaigeMiller]

---

@alepage wrote:
this script is not working.

---

Please explain further, as I said earlier in this thread, very brief explanations are rarely sufficient.

[yabwon]

Explain what you want your code to do. 

[alepage]

I want to map company ='A' if the macro variable &cie = b1

and map company ='B' if the macro variable &cie=b2

[PaigeMiller]

---

@alepage wrote:

I want to map company ='A' if the macro variable &cie = b1

and map company ='B' if the macro variable &cie=b2

---

Of course even with this brief description, we don't know if b1 is a variable in your data set or a value of the variable. Similarly for b2. And we don't know if the value of &cie is supposed to be a text string or the name of a variable or something else. These very brief problem descriptions are rarely sufficient.

Please explain in words the problem you are trying to solve using the macro variable, making it clear what &cie contains and what b1 and b2 represent.

Also, you didn't provide a data set (which you should always do), so that would make things clearer. Use these instructions and examples to provide a data set.

[Quentin]

One of the key parts to learning the macro language is to learn the difference between %IF and IF.  

If you want to use the macro language to decide which SAS code the macro will generate, you use the %IF statement.  

It sounds like you might want:

%let cie=b2;

data class;
  format company $1.;
  set sashelp.class;
  
  %if &cie=b1 %then %do;
    company="A";
  %end;
  %else %if &cie=b2 %then %do;
    company="B";
  %end;
run;

[alepage]

ERROR: Nesting of %IF statements in open code is not supported. %IF ignored.
ERROR: Skipping to next %END statement.

[PaigeMiller]

You seem unwilling to explain in detail what you are trying to do. This would help greatly and probably you would already have an answer if we had a better explanation.

The specific error message is that you cannot use nested %IFs outside of a macro in SAS, and is an entirely different problem than the one you started the thread with. But since you haven't shown us your code and haven't explained the points that several people have mentioned, its nearly impossible to help.

Please don't be so reluctant to provide the information and detail we have asked for. Please be generous with information.

[Quentin]

Sorry, my macro code will only work if the code is inside a macro definition.

[FreelanceReinh]

---

@Quentin wrote:

Sorry, my macro code will only work if the code is inside a macro definition.

---

It will also work if the "nesting" is avoided by omitting the %else keyword.

[Tom]

---

@alepage wrote:
ERROR: Nesting of %IF statements in open code is not supported. %IF ignored.
ERROR: Skipping to next %END statement.

---

You can either remove the %ELSE and make each %IF independent.

%if &cie=b1 %then %do;
    company="A";
%end;
%if &cie=b2 %then %do;
    company="B";
%end;

Or perhaps you don't need the second %IF at all and can instead just use the %ELSE.

%if &cie=b1 %then %do;
    company="A";
%end;
%else %do;
    company="B";
%end;

[FreelanceReinh]

Alternatively, you can nest %SYSFUNC function calls instead of %IF statements:

company="%sysfunc(choosec(%sysfunc(whichc(&cie,b1,b2)),A,B))";

This code can be generalized easily to handle more than two value pairs. You can also specify a value (for variable COMPANY) indicating that macro variable CIE contains an unexpected value:

company="%sysfunc(choosec(%sysfunc(whichc(&cie,b1,b2))+1,?,A,B))";

(Remember that WHICHC returns zero in that case, so the +1 shifts the first argument of the CHOOSEC function appropriately.)

Or the same using DATA step logic:

company=choosec(whichc("&cie","b1","b2")+1,"?","A","B");