What are you trying to do? Please explain.
In the meantime let's look at your data step and see what it is saying to do.
First let's fix the indentation to make it easier for human's to read.
DATA theData;
SET one;
OUTPUT;
IF _N_ THEN DO;
IF id = 2 THEN DO;
SET two (WHERE=(id = 5));
OUTPUT;
END;
END;
RUN;
The first thing to notice is the value of _N_ (unless you explicit modify it) will also be some positive number. So we can remove the first IF block as it will always execute.
DATA theData;
SET one;
OUTPUT;
IF id = 2 THEN DO;
SET two (WHERE=(id = 5));
OUTPUT;
END;
RUN;
So the first two statements mean that it will read observations from ONE and then immediately write them out to THEDATA.
When the value of ID is 2 then it will attempt to read an observation from TWO, but only the subset of TWO where the value of ID is 5. When it finds one it will write a second observation out for this observation from ONE.
One thing you need to learn is that most data steps do not terminate at the RUN statement. Instead they terminate at a SET/MERGE/UPDATE statement or an INPUT statement when they attempt to read past the end of the inputs. So in this data step since there are TWO separate SET statements there are two places where you might read past the end of the input. So the normal one where you read past the end of the primary input dataset ONE. But also the secondary one where you have more observations in ONE with ID=2 than there are observations in TWO with ID=5. In that case the data step will end there, potentially before it has finished reading all of the data from ONE.
So let's try it. First let's make the test data. NOTE: Do not indent the DATALINES; statement or the lines of data themselves. That will just cause confusion about what the lines contain.
DATA one;
INPUT id v3 v4;
DATALINES;
1 10 100
2 15 150
3 20 200
;
DATA two;
INPUT id v3 v4;
DATALINES;
4 1000 10000
5 1500 15000
5 2000 20000
7 800 30000
;
And run it
3591 DATA theData;
3592 SET one;
3593 OUTPUT;
3594 IF id = 2 THEN DO;
3595 SET two (WHERE=(id = 5));
3596 OUTPUT;
3597 END;
3598 RUN;
NOTE: There were 3 observations read from the data set WORK.ONE.
NOTE: There were 1 observations read from the data set WORK.TWO.
WHERE id=5;
NOTE: The data set WORK.THEDATA has 4 observations and 3 variables.
So it read read all three observations from ONE, so the extra SET statement did not cause it to end early.
It read in only one observation from TWO since there was only one observation from ONE that had ID=2 so it could go into that branch of the code.
And it wrote out 4 observations. The ones read from ONE and the extra written inside the IF/THEN block.
So let's see what we get.
proc print;
run;
Results:
Obs id v3 v4
1 1 10 100
2 2 15 150
3 5 1500 15000
4 3 20 200
Looks like it did what you asked. It read the first observation from ONE and wrote it. It read the second observation from ONE and wrote it. And then read the first observation in TWO that had ID=5 and which caused it to overwrite all three variables with the values from TWO and then wrote out another observation. Then it read the third observation from ONE and wrote it out. Then it tried to read a fourth observation from ONE and stopped.
