Hi
Linebreaks are not preserved by the multi-line prompt.
As a possible workaround I suggest to use a prompt definition like this:
This will give you an individual macro variable for each line. See part of the log below. The name of the prompt used in this example is MULTILINE.
32 %put _user_;
GLOBAL MULTILINE line1
GLOBAL MULTILINE0 2
GLOBAL MULTILINE1 line1
GLOBAL MULTILINE2 line2
GLOBAL MULTILINE_COUNT 2
You can then use the individual macro variables to put together your text that you need. I agree not the most elegant way, but might be a possible workaround.
This is an example code to handle the multiple macro variables
%macro generateText;
%local i;
%global newMultiline;
%let newMultiline =;
%if &MULTILINE_COUNT = 1 %then %do;
%global MULTILINE1;
%let MULTILINE1 = &multiline1;
%end;
%do i = 1 %to &MULTILINE_COUNT;
%let newMultiline = &newmultiline.^{NEWLINE}&&multiline&i;
%end;
%mend;
%generateText
ods escapechar="^";
ods text="&newMultiline";
proc print data=sashelp.class;
run;
Bruno
... View more
Hi Santanu
Since you have access to SAS, try uploading some other data and see how this works. I also attached a SAS data set create with SAS 9.4 on a Linux machine for testing.
I suggested you contact SAS technical support for this problem.
Bruno
... View more
Chris
Looking at the graph seems like the label for the axis is just the other way around
Here is the code in question:
proc sgplot data=message_times;
series x=post_date y=count;
xaxis minor label='Messages';
yaxis label='Time created' grid;
run;
Bruno
... View more
Hi
I recommend to store just the date as DATE9. value in a macro variable. From there all sorts use uses are possible.
Have a look at the sample code below.
%let cutdt = 01jan2011;
* use as date constant ;
data want;
somedate = "&cutdt"d;
format someDate worddate.;
run;
* a new formatted date value as text;
%let newDate = %sysfunc( putn(%sysevalf("&cutdt"d), ddmmyyp10.));
title "Date as of &newDate";
proc print data=want;
run;
Bruno
... View more
Hi
With SAS 9.4 I would go for ODS LAYOUT, this will give you a lot of flexibility on where on the page you want to position your output.
See a sample program below
options
orientation=portrait
papersize="ISO A4"
topmargin=2cm
bottommargin=2cm
leftmargin=2.5cm
rightmargin=1.5cm
nodate
nonumber
nocenter
;
title;
footnote;
ods pdf file="c:\temp\sample.pdf" nogtitle nogfootnote;
ods graphics / outputfmt=pdf;
title "Overall titel";
footnote "Overall footnote";
ods layout absolute;
ods region x=0cm y=0cm height=6cm style={background=cx4dbfbc};
title "proc print 1";
proc print
data=sashelp.class(obs=5)
style(report) = { width=100pct }
;
where sex = "F";
run;
title;
ods region x=5cm y=6.5cm height=10cm width=10cm style={background=cxd2691e};
title "proc sgplot";
ods graphics / height=8cm width=10cm;
proc sgplot data=sashelp.cars;
vbar type / group=Origin;
run;
ods region x=0cm y=17cm height=7cm style={background=cxffd700};
title "proc print 2";
proc print
data=sashelp.class(obs=5)
style(report) = { width=100pct }
;
where sex = "M";
run;
title;
ods layout end;
ods pdf close;
Bruno
... View more
DMS Display Manager System. It is now called the SAS windowing environment
You start SAS directly on your platform and not using some client GUI like SAS Enterprise Guide or SAS Studio
Bruno
... View more
Hi Santanu
Can you ask the creator of the SAS data set to send you the Proc CONTENTS output?
Was the SAS dataset created by SAS or some other tool?
Is it possible to attach the SAS dataset to this post?
Bruno
... View more
Hi Santanu
It would help if you could post the output of the Proc CONTENTS from the original SAS data set, if possible, and the one you uploaded to be used in SAS Studio.
Bruno
... View more
Hi
It is possible to create a SAS data set with 0 obersvations and 0 variables, see code below. Run Proc CONTENTS on the data set and have a look at the output. As a general advice, I would avoid the use of physical names for a SAS data set, but rather use a LIBNAME statement.
data new; stop;
run;
proc contents data=new;
run;
proc print data=new;
run;
Bruno
... View more
Hi
From the error message it looks like your code is running on a Unix/Linux using SAS9.3
Your SAS server does not have access to your local filesystem on your PC
Use the File -> Import Data task to import xls files
Bruno
... View more
Hi
You can define interaction for object which are in the Canvas area. This is also true for object within a prompt container.
Report objects in the Section- or Report-Prompt area do not support interactions, as they are build in.
Bruno
... View more
Scott
I guess you need to set the LOCKTABLE= option on both statements. See also here FedSQL Statement Table Option Syntax
See an example below:
data class class_cols;
set sashelp.class;
output class;
run;
proc ds2;
data test(overwrite=yes);
dcl package hash h();
dcl double num;
method init();
if 0 then set class (locktable=share);
h.definekey('name');
h.definekey('sex');
h.definedata('age');
h.definedata('height');
h.definedata('weight');
h.dataset('{select * from class {options LOCKTABLE= SHARE} where sex=''F''}');
h.definedone();
num=h.num_items;
put num=;
end;
enddata;
run;
quit;
data test;set test;run;
Bruno
... View more
Hi Jan
Thanks for pointing this out. Some SAS/ACCESS to Interfaces will pass down the OBS= data set option as part of the generated SQL Query. There might be various ways to optimize this, depending on the DBMS used.
Bruno
... View more
Hi
Please note, that the NOBS= option of the SET statement can only be used with SAS data sets. If your data is coming from a DBMS like Oracle, DB2 etc, then this approach can not be used. Instead you have to count the number of rows.
To run code contionally, one usually uses the SAS Macro Language.
Find below an example that shows how to count the rows, and then run some DATA Step.
%macro createData(dsn=);
%local rowCount;
proc sql noprint;
select
count(*)
into
:rowCount trimmed
from
&dsn
;
quit;
%put NOTE: &=rowCount;
%if &rowCount > 0 %then %do;
data newTable;
set &dsn;
run;
%end;
%else %do;
%put NOTE: &sysmacroname &dsn is empty;
%end;
%mend;
%createData(dsn=xora.tempcars)
Bruno
... View more
I guess the main difference is that Proc CONTENTS will read the desriptive part of a SAS data set directly (only one data sets). Whereas the SASHELP.V... and the DICTIONARY tables potentially have to deal with several tables and use a "longer" way till they get the information.
Bruno
... View more
