Do NOT use the CAT series of functions with %SYSFUNC().   First of all you don't need them.  To concatenate text in macro code just write the text next to each other.  Remember to use a period to mark the end of the macro variable name so the macro processor does not look for the TIMEM macro variable instead of the TIME macro variable. %let time=%sysevalf(&timetot-&timeremain); %put time used: &time.m; Second because the CAT series of functions can take both numeric and character arguments it drives the %SYSFUNC() macro function crazy trying to decide how to treat the text you have given it.    What should it do with a string like 1E2 ?  Is that supposed to be the number 100?    If you have a need for the CATX() function in macro logic you could use this macro instead of trying to get it to work with %sysfunc().   https://github.com/sasutils/macros/blob/master/catx.sas The CAT... series of functions do not work well with %SYSFUNC() because they can accept either numeric or character values. So %SYSFUNC() has to try and figure out if the value you passed is a number or a string. Which can cause unwanted messages in the LOG and worse. Example issue with %sysfunc(catx()): 1 %put |%sysfunc(catx(^,a,,c))|; ERROR: %SYSEVALF function has no expression to evaluate. |a^c|   ... View more

I could not find the old original ANSI Standard SQL from 1992 that SAS PROC SQL is based on to check, but it looks like you are right that others are applying the term "simple" (usually in quotes) to the expression/value version of the CASE syntax.   Personally I don't find either of them simple, but in my experience the version where each WHEN clause has a boolean expression instead of a value is the "normal" way that CASE expressions are used. ... View more

You did not attach anything.   If you have text you want to share use the Insert Code button (it looks like </>).   If you have a picture you want to share use the Insert Photos button (looks like SLR camera). ... View more

Make a new variable in the CHILD dataset that is one less than the child ID value and then merge on that.  Or do both in one step using PROC SQL. data parent; input parentid name :$20.; cards; 1000 Smith ; data child; input childid age ; cards; 1001 10 ; proc sql; create table want as select * from parent full join child on parent.parentid = child.childid -1 ; quit; ... View more

Look at the RESP file to see the error message that the API you are querying generated.   Two things.  There does not appear to be a variable named I_COMMODIT that you are requesting. It does not like the spaces in the GET= option. Also it looks like it includes all of the extra variables you mention in the filters, so you can remove I_COMMODITY from the list of variables provided to GET=. filename resp temp; proc http   method="get"   url='https://api.census.gov/data/timeseries/intltrade/imports/hs'   query=(    "get" = "CTY_CODE,CTY_NAME,CON_QY1_MO,I_COMMODITY_SDESC,GEN_VAL_MO" "COMM_LVL" = "HS10" "YEAR"="2025" "MONTH"="01" "I_COMMODITY"="76*"   )   verbose   out=resp ; run; Once you have the file it looks like you can read it simply by just removing the square brackets. data want; infile resp dsd firstobs=2 truncover ; input @; _infile_=compress(_infile_,'[]'); input (CTY_CODE CTY_NAME CON_QY1_MO I_COMMODITY_SDESC GEN_VAL_MO COMM_LVL YEAR MONTH I_COMMODITY) (:$100.) ; run;     ... View more

I don't know about you but I actually like to LOOK at my data.  That is very difficult when the variables are placed randomly.  There is nothing worse than trying to debug something and looking at a dataset here the whole first screen is full of long empty character variables of low importance. ... View more

The data step compiler adds the variables to the dataset in the order.  So to change the order make sure the code references the variables in the order you want.    Not all references actually cause SAS to need to place the variable in the dataset at that time. For example the DROP or KEEP statement does not impact order (even if it is the first place the variable is referenced).  Instead they just set flags to indicate if the variable will be written to the output dataset.   The data step compiler will also set the type (and storage length) of the variable at the first place where it HAS to.  But not all references will set the type.  For example the RETAIN statement will set the variables place, but it will not determine its TYPE.  That will be (or has been) determined by where it is used.    So you can use RETAIN to set the order.  Just be sure that your data step will not be impacted by the actual purpose of a RETAIN statement, that the variables value is not clear when a new iteration starts.   Example: 73 data _null_; 74 keep height age name ; 75 set sashelp.class(obs=1); 76 put (_all_) (=/); 77 run; Name=Alfred Sex=M Age=14 Height=69 Weight=112.5 NOTE: There were 1 observations read from the data set SASHELP.CLASS. NOTE: DATA statement used (Total process time): real time 0.00 seconds cpu time 0.00 seconds 78 79 data _null_; 80 retain height age name ; 81 set sashelp.class(obs=1); 82 put (_all_) (=/); 83 run; height=69 age=14 name=Alfred Sex=M Weight=112.5 NOTE: There were 1 observations read from the data set SASHELP.CLASS. NOTE: DATA statement used (Total process time): real time 0.00 seconds cpu time 0.00 seconds   Notice that the RETAIN statement also set the case of the variable names and the KEEP statement did not.   To really set the order you should probably just DEFINE all of the variables first using a LENGTH statement. data want; length age height 8 Sex $1 Name $10 weight 8; set sashelp.class(obs=1); run; proc contents varnum; run; But if you don't know how to define the existing variable then perhaps you could just use a series of references to the dataset to let the data step compiler find it for you.  Say you want to move AGE to the front and leave the others in place. data want; set sashelp.class(keep=age); set sashelp.class; run;   ... View more

Use PROC CONTENTS to look at the datasets. Do the variables have any user defined formats attached to them?   Use PROC FORMAT to look at the format catalog. Are the formats that exist int eh format catalog the same as those attached to the vairables?   If both are YES then all you need to do is add the format catalog to the FMTSEARCH option and SAS will use those formats when displaying the variable's values.   If both (or either) is NO then you will need to figure it out yourself. You might look at the set of values the formats can decode and then compare those to the set of values that appear in the dataset for the different variables.  For example say you have format named YESNO that displays 1 as "YES" and 0 as "NO".  And you have variable named PRESENT that only has the values 0 and 1.  In that case you might deduce (quess) that you should attach the YESNO format to PRESENT. ... View more

How do you know what formats to apply? You did not include any example code that was applying formats to variables in your original post. ... View more

Actually you can take advantage of a quirk of PROC IMPORT.  If it sees that all observations of a variable are quoted it decides the variable must be character.  So use the ~ modifier to write a CSV file where everything is quoted (whether the value needs quotes or not). %let dsn=sashelp.cars; filename csv temp; * Write header row ; proc transpose data=&dsn(obs=0) out=names ; var _all_; run; data _null_; file csv dsd ; set names; put _name_ ~ @ ; run; * Appedn data rows ; data _null_; file csv dsd mod ; set &dsn ; put (_all_) (~); run; proc import dbms=csv file=csv out=want replace; run; proc contents data=want varnum; run;                         ... View more

@TK12 wrote: nvm figured it out; below works compute after ord;   text="";   len=(ord ne 3);   line "@R/RTF'\fs8" text $varying. len; endcomp; That will always write a line because you included a string literal in the LINE statement. You need to write ZERO bytes in the LINE statement for PROC REPORT to not produce a line. I am not sure what you want to do but if the goal is to either write "@R/RTF'\fs8" or not have a line at all you need to do something like this:   compute after ord;   text="@R/RTF'\fs8";   len=(ord ne 3)*length(text);   line text $varying. len; endcomp; So when ORD is 3 then LEN is set to ZERO. Otherwise LEN is set to the length of TEXT. Perhaps it would be clearer to do it this way. compute after ord; if ord eq 3 then  text="@R/RTF'\fs8"; else text=" ";   len=lengthN(text);   line text $varying. len; endcomp; The newish LENGTHN() function gets the length of string ignoring the ALL of the trailing spaces.  So a string with only spaces will have a length of zero instead of the length of one that the older LENGTH() function calculates. ... View more

Are you sure you don't want to write a fixed length file? Perhaps one with extra characters between the fields to make it easier for humans to read? data _null_; set sashelp.class; put name $char10. "|" sex $1. "|" age 4. "|" height 6.2 ; run; Results Alfred |M| 14| 69.00 Alice |F| 13| 56.50 Barbara |F| 13| 65.30 Carol |F| 14| 62.80 ... ... View more

Please show the SAS code you used to write the file that did not work.  Note that using the DSD option implies that the leading/trailing spaces will be removed.   Why exactly would you want to include leading or trailing spaces into a delimited text file?   How can you know how many trailing spaces to include?  SAS character variables are fixed length.  So they are always padded with enough spaces to fill them.   If you know the length you want to print use the $VARYING format.  That requires a separate variable with the length to be printed. Try this data step to see how it works. data _null_; length string $10 ; string=" abc"; do i=0 to 10; put '|' string $varying100. i '|'; end; run;   ... View more