how to compare a likert scale response among multiple groups

[cpeloquin]

Hello. This is my first time analyzing questionnaire results. I would like to analyze a likert scale response (5 levels: very satisfied (coded as a 5), satisfied (4), neither satisfied nor dissatisfied (3), dissatisfied (2), very dissatisfied (1)) among 4 groups (coded as A, B, C, D). I am at a loss on how to approach this as well as how to interpret the result. Many thanks for any help you might be able to give. Attaching a small subset of my dataset below.

Christine

data survey;
input group $1. q1;
datalines;
D 2
D 1
A 3
D 1
A 5
D 2
C 4
B 3
D 5
D 1
A 4
B 3
C 3
D 2
A 1
B 4
D 1
D 5
D 1
B 1
D 5
B 2
D 3
B 4
B 2
run;

[Ksharp]

/*
Using One-Way ANOVA Tests of non-parameter method ?
(Kruskal-Wallis test)

P.S. 
Since it is question about statistic ,
Better post it at Stat Forum
https://communities.sas.com/t5/Statistical-Procedures/bd-p/statistical_procedures
and calling @Rick_sas @StatDave_sas



From the result, Kruskal-Wallis test P value is 0.6 ,
that means there is no evidence to prove the difference between groups.
*/




data survey;
input group $1. q1;
datalines;
D 2
D 1
A 3
D 1
A 5
D 2
C 4
B 3
D 5
D 1
A 4
B 3
C 3
D 2
A 1
B 4
D 1
D 5
D 1
B 1
D 5
B 2
D 3
B 4
B 2
;
proc npar1way wilcoxon  data=survey;
class group;
var q1;
/*exact wilcoxon;*/
run;






/*
If you want compare between two group ,
Using One-Way ANOVA Tests of parameter method 



From the result:
i/j 1 2 3 4 
1   0.9406 0.9974 0.7738 
2 0.9406   0.9140 0.9752 
3 0.9974 0.9140   0.7827 
4 0.7738 0.9752 0.7827 

The table of ANOVA above means there is no evidence to prove the difference between groups.
*/
proc glm   data=survey ;
class group;
model q1=group/solution ;
means group/hovtest;
lsmeans group/pdiff  adjust=tukey  ;
run;

calling @Rick_SAS  @StatDave  @SteveDenham @lvm 

[cpeloquin]

Thank you so very much. I really appreciate you taking the time to do this. Much gratitude.

[StatDave]

If your groups have no natural ordering, then you could take either a modeling approach using a cumulative logistic model in PROC LOGISTIC, or a nonmodeling approach using the asymmetric lambda or uncertainty statistics in PROC FREQ. Both analyses are shown below.

proc freq; 
table group*q1/measures; 
run;
proc logistic; 
class group/param=glm; 
model q1=group; 
lsmeans group/diff plots=none; 
run;

The type 3 test for GROUP in the logistic model shows no significant differences among the groups (p=.55) and the pairwise tests of differences confirm this. The lambda (C|R) is also not significant, while the uncertainty (C|R) statistic is barely significant. See "Statistical Computations:Measures of Association" in the Details section of the PROC FREQ documentation for details on these last two statistics.

[cpeloquin]

Thank you StatDave for your generosity and knowledge. Many many thanks!