Unable to calculate Type III fixed effects in proc GLIMMIX

[ehdezsanabria]

Thank you for taking your time to read my message. I am working with a data set containing proportions of bacterial sequences found in human subjects. These subjects were subjected to two treatments (treatment A contains 39 subjects and there are 40 volunteers in treatment B). Measurements were performed at three time points (V1, V2 and V3). Individuals were presenting either severe or not severe symptoms of disease (sev/not).

I want to compare the sequences between treatments and I used proc GLIMMIX as follows:

PROC GLIMMIX DATA=new method=laplace empirical;
CLASS trt tpt sym ;
MODEL Akkermansia= tpt trt sym  tpt*trt*sym/ link=log dist=negbin DDFM=CONTAIN OFFSET=loglib ; 
random tpt/ subject=trt type=ar(1);
LSMEANS tpt*trt*sym/diff ilink; 
NLOPTIONS maxiter=500 tech=nrridg;
RUN;

The issue is that the fixed effects of "trt" and "tpt" are not calculated using this syntax.

I also tried using the intercept as the repeated "variable":

PROC GLIMMIX DATA=new method=laplace empirical;
CLASS trt sym tpt ;
MODEL Akkermansia= tpt trt sym tpt*trt*sym/ link=log dist=negbin DDFM=CONTAIN OFFSET=loglib ; 
random intercept/ subject=trt type=ar(1);
LSMEANS trt*sym/diff ilink; 
NLOPTIONS maxiter=500 tech=nrridg;
RUN;

But I am still unable to calculate the "trt" effects. 

I will appreciate if you can help me to understand why this effect is not calculated and how can I do to resolve the issue. I think it has to do with the syntax but I am not sure. 

Once again, thank you for your time!

Best wishes,

Emma

[SteveDenham · Accepted solution]

Try the following:

PROC GLIMMIX DATA=new method=laplace empirical;
CLASS sample trt sym tpt;
MODEL Akkermansia=  trt|sym|tpt/ link=log dist=negbin ddfm=bw  OFFSET=loglib ; 
random tpt/ subject=sample type=chol;
LSMEANS trt*sym*tpt/diff ilink; 
NLOPTIONS maxiter=500 tech=nrridg;
RUN;

This fits a repeated measures design, where V1, V2 and V3 are repeated measures on the subject, which here is the sample.  I think this more closely represents the data and the factors involved.  This analysis points to a significant 3 way interaction, so you may want to slice your comparisons for each visit, to look at differences between treatments and whether these are mediated by symptom.

Steve Denham