Calcite | Level 5

Split plot design with more than two factors

Hi, this is my first post on SAS. I have a split plot design in 5 factors. Factors A, B, and C have 3 levels and are hard to change factors applied to the main plots. Each main plot contains one combination of A,B,C (so 27 main plots in the 3^3 main plot factorial). The sub plot receives a 3^2 factorial in easy to change factors (D, E). Every example I find only discusses how to write the SAS program for Factors A and B. I replicate the entire design twice.

I cant find anything on how to adjust the below SAS code to handle 3 factors in the main plot and two factors in the subplots.

Simple Split plot in 2 factors:

```proc mixed;
class A B Block;
model Y = A B A*B;
random Block A*Block;
run;```

Can someone help or point me in the right direction? much appreciated.

8 REPLIES 8

Re: Split plot design with more than two factors

If I understand your design you can think of it this way.

``````data split;
do block=1,2;
whole=0;
do a=1 to 3;
do b=1 to 3;
do c=1 to 3;
whole+1;
sub=0;
do d=1 to 3;
do e=1 to 3;
sub+1;
y = rannor(13456);
output;
end;
end;
end;
end;
end;
end;
run;
proc print;
run;

proc mixed data=split method=type1;
class block whole sub;
model y = whole sub whole*sub;
random block whole*block;
run;
proc mixed data=split method=type1;
class block a b c d e;
model y = a|b|c|d|e;
random block a*b*c*block;
run;``````
Calcite | Level 5

Re: Split plot design with more than two factors

Thank you for the quick reply and for the example. Is the statement 'do block=1,2;' for the two replicates; Did I understand this correctly? I will run this example and try to see if I understand how it is structured. At the moment I dont fully understand the reason for the two PROC MIXED models. Forgive me, I am not all that experienced in SAS (yet)

Re: Split plot design with more than two factors

This first one is the analysis in terms of a single treatment whole plot and subplot.  27 whole plots treatments  and 9 subplots.

This is a check for the second MIXED where we partition the whole plots (df=26) into the factorial effects a|b|c.  Same for SUB df=8 and SUB*WHOLE df=208 are partitioned into all the many effects of a|b|c|d|e that remain.

Re: Split plot design with more than two factors

Output from second PROC MIXED.

Calcite | Level 5

Re: Split plot design with more than two factors

Thank you so much. That makes it really clear. I can see that the SS are in agreement. This makes perfect sense to me.

Re: Split plot design with more than two factors

Regarding your question about block=1,2 I assumed that when you said 2 replicates that you meant the experiment was in Randomized Complete Blocks.  If not then I don't believe the model with Random BLOCK and BLOCK*Whole Plot is correct.  Do you have a plot plan or other schematic drawing of the experiment.

Calcite | Level 5

Re: Split plot design with more than two factors

Hi Data_null__, here is a study diagram of the experiment. the replication happens at the sub-plot level. It is different than replicating the entire experiment. The study diagram only shows 3 main-plot treatment combinations out of 27.

Re: Split plot design with more than two factors

@shaz71 wrote:

Hi Data_null__, here is a study diagram of the experiment. the replication happens at the sub-plot level. It is different than replicating the entire experiment. The study diagram only shows 3 main-plot treatment combinations out of 27.

Looks like there are no complete blocks.  Looks like subplots are blocked (REP 1/2) within whole plots.  I don't think the model with BLOCKS is correct for this design.

Discussion stats
• 8 replies
• 3124 views
• 0 likes
• 2 in conversation