replace values in list of variables using macro

[panda]

Hi,

I'd like to replace values of a list of similar variables (replace 'C' with '2') for 12 variables:

data want;
   set dat;
  if var01 = 'C' then var01 = '2';
  if var02 = 'C' then var02 = '2';
  if var03 = 'C' then var03 = '2';
  ...
  if var12 = 'C' then var12 = '2';
run;

How can I simplify this code with macro/loop? I tried the following codes but did not work:

%let var_list = var01-var12;
%macro loop(var_list);
%local i next_var;
data want;
   set dat;
   %do i = 1 %to %sysfunc(countw(&var_list));
   %let next_name = %scan(&var_list, &i);
   if &next_var = 'C' then &next_var = '2';
   %end;
run;
%mend;
%loop(&var_list); 

Any idea? Thanks!

[PaigeMiller · Accepted solution]

No macro needed. Use an ARRAY.

data want;
    set dat;
    array v var01-var12;
    do i=1 to dim(v);
        if v(i)='C' then v(i)='2';
     end;
    drop i;
run;

[panda]

Thanks it worked!

[Reeza]

How complicated does this get? Would a format be appropriate as well - do you need actual recoding to numeric values as well? Or will a character variable be sufficient?

[panda]

a character variable is sufficient.