proc tabulate: bold row if column has value

[Konkordanz]

Hi,

I tried several options but it doesnt work for me. What I want: A hole row shall be bold, if one column has a specific value.

For example with the sashelp.cars-data: I want to have a bold row, if the Make-Value is "Kia".

Thank you for help!

proc tabulate data=sashelp.cars;
class make type;
var msrp;
table make,type*msrp;
run;

[Ksharp]

Use PROC REPORT instead.

proc report data=sashelp.cars nowd;
columns make msrp,type;
define make/group style=header;
define type/across;
define msrp/analysis sum  ' ';
compute make;
 if make='Kia' then do;
  call define(_row_,'style','style={fontweight=bold}');
  call define(_col_,'style','style=header');
 end;
endcomp;
run;

[Konkordanz]

Right, with proc-report its doable. But is there also a solution for the proc-tabulate-step?

[Ksharp]

OK. It is not easy for PROC TABULATE.

But how about this one ?

proc format;
value $ fmt
'Kia'='bold'
other='light'
;
run;

proc tabulate data=sashelp.cars;
class make type;
classlev make/style={fontweight=$fmt.};
var msrp;
table make*{style=<parent>{background=white foreground=black}},type*msrp;
run;