Sign % in text of macro variable

[SASdevAnneMarie]

Hello,

I'm trying to resolve the macrovariable &PROFILE that has a text: "ne devra représenter plus de 20 %du profil de gestion".

I get the Warning message: WARNING: Apparent invocation of macro DU not resolved.

Do you know please how to avoid this message?

Thank you very much!

Best regards,

Marie

[PeterClemmensen]

Use a proper macro quoting function

data _null_;
   call symputx('profile', 'ne devra représenter plus de 20 %du profil de gestion');
run;

%put %superq(profile);

[yabwon]

haha! We have almost exactly the same answers 🙂 🙂

B-)

[SASdevAnneMarie]

I still have the same warning, my code is:

obj.row_start();
obj.format_cell(data:
"OBJECTIFS :" , overrides: "font_face=Calibri just=left font_weight=bold color=cx338AFF font_size=10pt width=2.6 cm");
obj.format_cell(data: %sysfunc(quote(%superq(PROFILE))) , overrides: "font_face=Calibri just=left color=black font_size=10pt ");
obj.row_end();

[SASdevAnneMarie]

Thank you!

[Kurt_Bremser]

The first argument to %SYSFUNC must be a data step function.

Belay that, somehow the coffee must not have worked today.

[SASdevAnneMarie]

Hello Kurt,
Thank you for your answer!
I didn't understand , %sysfunc(quote(%superq(PROFILE_NAME))) worked in my code for another problem.
I can't use %sysfunc?

[yabwon]

try %superq()

data _null_;
  call symputX('PROFILE', 'ne devra représenter plus de 20 %du profil de gestion', "G");
run;

%put %superq(PROFILE);

[SASdevAnneMarie]

Thank you!

I still have the same warning, my code is:

obj.row_start();
obj.format_cell(data:
"OBJECTIFS :" , overrides: "font_face=Calibri just=left font_weight=bold color=cx338AFF font_size=10pt width=2.6 cm");
obj.format_cell(data: %sysfunc(quote(%superq(PROFILE))) , overrides: "font_face=Calibri just=left color=black font_size=10pt ");
obj.row_end();

[yabwon]

hmmm..

try with %qsysfunc()

data _null_;
  call symputX('PROFILE', 'ne devra représenter plus de 20 %du profil de gestion', "G");
run;

%put %qsysfunc(quote(%superq(PROFILE)));

[SASdevAnneMarie]

Hello, thank you!
%qsysfunc need a put, beacause I get the error:
ERROR 22-322: Syntax error, expecting one of the following: a name, a quoted string, a numeric constant, a datetime constant,
a missing value, arrayname, (, +, -, INPUT, NOT, PUT, ^, _NEW_, ~.
I can't write a put, beacause I have an ods object code:


obj.row_start();
obj.format_cell(data:
"OBJECTIFS :" , overrides: "font_face=Calibri just=left font_weight=bold color=cx338AFF font_size=10pt width=2.6 cm");
obj.format_cell(data: %sysfunc(quote(%superq(PROFILE))) ,
overrides: "font_face=Calibri just=left color=black font_size=10pt ");
obj.row_end();

[Tom]

Not sure what this statement is. Why does the first line end in a comma and not a semi-colon?  So assuming you want to run this statement:

obj.format_cell(data: %sysfunc(quote(%superq(PROFILE))) 
               ,overrides: "font_face=Calibri just=left color=black font_size=10pt ")
;

Does that statement allow you to use single quotes instead of double quotes?  Those will prevent the macro process from trying to evaluate the % and & triggers in the string.

obj.format_cell(data: %sysfunc(quote(%superq(PROFILE),%str(')))
               ,overrides: "font_face=Calibri just=left color=black font_size=10pt ")
;

Also does the syntax of that statement allow a variable or function instead of a string literal?

obj.format_cell(data: symget('PROFILE') 
               ,overrides: "font_face=Calibri just=left color=black font_size=10pt ")
;

[SASdevAnneMarie]

Hello Tom,

Thank you for your suggestions.
Unfortunately it doesn't work. (
I added the code and xlsx file.

Best regards,
Marie

[yabwon]

and how about this:

data _null_;
  call symputX('PROFILE', 'ne devra représenter plus de 20 %du profil de gestion', "G");
run;

obj.row_start();
obj.format_cell(data:
"OBJECTIFS :" , overrides: "font_face=Calibri just=left font_weight=bold color=cx338AFF font_size=10pt width=2.6 cm");
obj.format_cell(data: %str(%')%superq(PROFILE)%str(%') ,
overrides: "font_face=Calibri just=left color=black font_size=10pt ");
obj.row_end();

for the format_cell data portion(according to the doc) can be enclosed in single quotes.

Bart

[yabwon]

or approach with `_temporary_variable_`?

data _null_;
  call symputX('PROFILE', 'ne devra représenter plus de 20 %du profil de gestion', "G");
run;


filename out "%sysfunc(pathname(WORK))";
ods html close;
ods html path=Out file="test.html";

data _null_;

  dcl odsout obj();
  obj.table_start();

  _temporary_variable_ = symget("PROFILE");
  drop _temporary_variable_;

  obj.row_start();
  obj.format_cell(data: "OBJECTIFS :", 
    overrides: "font_face=Calibri just=left font_weight=bold color=cx338AFF font_size=10pt width=2.6 cm");
  obj.format_cell(data: _temporary_variable_,
    overrides: "font_face=Calibri just=left color=black font_size=10pt ");
  obj.row_end();


  obj.table_end();
run;
ods html close;
ods html;

Bart