@HALOBEAST999:
NOTE: I've just edited the first (array) solution since @FreelanceReinh has found an actual error in the code - it wasn't populating the array for numeric variables' frequencies NQ and suggested a 2-dimensional array instead to keep a single LINK block.
That's right, MEANS doesn't work with character analytical variables. But in 10-20 minutes (depending on your SAS exposure) you can write 17 lines of DATA step code to do what you want for all variables in the input data set regardless of their data type. For example (corrected code thanks to @FreelanceReinh😞
data have ;
input n1 c1:$1. n2 c2:$2. n3 c3:$3. ;
cards ;
0 . 00 AA 000 .
. B 11 . 111 BBB
2 C . CC . CCC
3 . . DD 333 DDD
. E 44 EE 444 .
5 F . FF 555 FFF
6 . 66 GG 666 GGG
7 H . HH . HHH
. I . . 888 .
9 . 99 JJ 999 .
;
run ;
data freq (keep = vname N_:) ;
set have nobs = nobs end = eof ;
array nn _numeric_ ;
array cc _char_ ;
array q [2, 1000000] _temporary_ ;
do over nn ; q [1,_i_] ++ cmiss (nn) ; end ;
do over cc ; q [2,_i_] ++ cmiss (cc) ; end ;
if eof ;
do over nn ; Vname = put (vname (nn), $32.) ; d = 1 ; link compout ; end ;
do over cc ; Vname = put (vname (cc), $32.) ; d = 2 ; link compout ; end ;
return ;
compout: N_null = q [d,_i_] ;
N_notnull = nobs - N_null ;
output ;
return ;
run ;
The hard-coded 100000 is supposed to exceed the number of either numeric or character variables in your input file. If you have more than that 😉 , you can bump it up to 1000000 or even 10000000 (at the expense of at most 150 MB of RAM).
If you're still averse to setting hard-coded limits of this kind, the SAS hash object is your friend:
data _null_ ;
if _n_ = 1 then do ;
dcl hash f (ordered:"D") ;
f.definekey ("vname") ;
f.definedata ("vname", "n_null", "n_notnull") ;
f.definedone () ;
end ;
set have end = eof ;
array nn _numeric_ ;
array cc _char_ ;
do over nn ;
Vname = put (vname (nn), $32.) ;
if f.find() ne 0 then call missing (N_null, N_notnull) ;
if cmiss (nn) then n_null ++ 1 ;
else n_notnull ++ 1 ;
f.replace() ;
end ;
do over cc ;
Vname = put (vname (cc), $32.) ;
if f.find() ne 0 then call missing (N_null, N_notnull) ;
if cmiss (cc) then n_null ++ 1 ;
else n_notnull ++ 1 ;
f.replace() ;
end ;
if eof then f.output (dataset:"freq") ;
run ;
Sometimes it's easier to write a simple DATA step program than to try fitting what you need in the Procrustean bed of an existing proc.
Note that the two programs above will work for any input data set. The only caveat is that if it has no numeric or no character variables, you'll get a harmless warning in the log saying that a zero dimension array is being defined.
Also note that for very large data sets, the array approach will work noticeably faster. This is because arrays items can be overwritten directly in place and therefore (unlike the hash object) do not involve moving data to the PDV and back.
Kind regards
Paul D.
