ODS EscapeChar style not work in html

[Blaine7]

I want to left justify one of my column header when running proc report. I refer to the question here:https://communities.sas.com/t5/ODS-and-Base-Reporting/How-Can-I-Make-Header-Justified-Left-Partially.... It is quite familiar to my question. One difference is I want to output a html. The solution works for rtf and pdf. Not works for html. 

Here is my example code:

data test;
length column1-column3 $200.;
column1="aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa"; column2="bbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbb "; column3="cccccccccccccccccccccccccccccccccccccccccccccccccc "; output;
run;

ods html file="****";
ods escapechar='~';
proc report data=test nowindows style(header)={just=c};
column ('aaaaa' column1 ('~S={just=l} bbbb' column2) ('~S={just=r} cccc' column3));
define column1 / display;
define column2 / display;
define column3 / display;
run;
ods HTML close;

Any suggestion would be appreciated.

[Hao_Luo]

This may works:

ods escapechar='~';
proc report data=test nowindows style(header)={just=c};
column ('aaaaa' column1 ('~S={just=l width=300%}bbbb' column2) ('~S={just=r width=300%}cccc' column3));
define column1 / display;
define column2 / display;
define column3 / display;
run;

Have no idea about the reason and feel pity about that. I may back to complete this.

[Blaine7]

Hi Luo, thanks for your response. I didn't see any difference with the code you provided. Did that work on your SAS console?

[Hao_Luo]

Yes, I am using SAS 9.4 TS1M8.

[Hao_Luo]

Just a quick try in SAS EG, this trick failed >_<

[Blaine7]

Yes. I am using SAS studio and it failed either.

[Ksharp · Accepted solution]

Try Traffic Light Format.

data test;
length column1-column3 $200.;
column1="aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa"; column2="bbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbbb "; column3="cccccccccccccccccccccccccccccccccccccccccccccccccc "; output;
run;

proc format;
value $ fmt
'bbbb'='l'
'cccc'='r'
other='c'
;
run;

ods escapechar='~';
proc report data=test nowindows style(header)={just=$fmt. };
column ('aaaaa' column1 ('bbbb' column2) ('cccc' column3));
define column1 / display;
define column2 / display;
define column3 / display;
run;

[Blaine7]

It works. Thanks a lot.