BookmarkSubscribeRSS Feed
adamhyman
Calcite | Level 5

If I have a sorted table like this:

DATA myfruit;

   INPUT fruit $40.;

   DATALINES;

APPLE
APPLE

APPLE
PEACH
PEACH

;

RUN;

I would like to add the "Count" column like this:

FruitCount
APPLE1
APPLE2
APPLE3
PEACH1
PEACH2

I know that I have to do something like this, I can't get it quite right.

data myfruit;

set myfruit;

     by fruit;

          Count = _N_;

run;

Any help would be greatly appreciated.

Thanks!
Adam

4 REPLIES 4
adamhyman
Calcite | Level 5

I worked it out, so am posting the solution.

data myfruit;

set myfruit;

     by fruit;

     retain count;

     if first.fruit then count = 1;

     else count + 1;

run;

MikeZdeb
Rhodochrosite | Level 12

hi ...

data myfruit;

set myfruit;

by fruit;

count + (-first.fruit * count) + 1;

run;

ps ... http://www.sascommunity.org/wiki/Tips:Between_and_Within_Group_Counters

Ksharp
Super User

Assuming your dataset has already sorted before.

DATA myfruit;
   INPUT fruit $40.;
   DATALINES;
APPLE
APPLE
APPLE
PEACH
PEACH
;
RUN;

data myfruit;
set myfruit;
if fruit ne lag(fruit) then count=0;
Count+1;
run;

Ksharp

Haikuo
Onyx | Level 15

Can also use DOW's counter:

data want;

  do count=1 by 1 until (last.fruit);

  set myfruit; by fruit;   output;

  end;

run;

Haikuo

hackathon24-white-horiz.png

2025 SAS Hackathon: There is still time!

Good news: We've extended SAS Hackathon registration until Sept. 12, so you still have time to be part of our biggest event yet – our five-year anniversary!

Register Now

How to Concatenate Values

Learn how use the CAT functions in SAS to join values from multiple variables into a single value.

Find more tutorials on the SAS Users YouTube channel.

SAS Training: Just a Click Away

 Ready to level-up your skills? Choose your own adventure.

Browse our catalog!

Discussion stats
  • 4 replies
  • 1694 views
  • 0 likes
  • 4 in conversation