If I have a sorted table like this:
DATA myfruit;
INPUT fruit $40.;
DATALINES;
APPLE
APPLE
APPLE
PEACH
PEACH
;
RUN;
I would like to add the "Count" column like this:
Fruit | Count |
---|---|
APPLE | 1 |
APPLE | 2 |
APPLE | 3 |
PEACH | 1 |
PEACH | 2 |
I know that I have to do something like this, I can't get it quite right.
data myfruit;
set myfruit;
by fruit;
Count = _N_;
run;
Any help would be greatly appreciated.
Thanks!
Adam
I worked it out, so am posting the solution.
data myfruit;
set myfruit;
by fruit;
retain count;
if first.fruit then count = 1;
else count + 1;
run;
hi ...
data myfruit;
set myfruit;
by fruit;
count + (-first.fruit * count) + 1;
run;
ps ... http://www.sascommunity.org/wiki/Tips:Between_and_Within_Group_Counters
Assuming your dataset has already sorted before.
DATA myfruit; INPUT fruit $40.; DATALINES; APPLE APPLE APPLE PEACH PEACH ; RUN; data myfruit; set myfruit; if fruit ne lag(fruit) then count=0; Count+1; run;
Ksharp
Can also use DOW's counter:
data want;
do count=1 by 1 until (last.fruit);
set myfruit; by fruit; output;
end;
run;
Haikuo
Are you ready for the spotlight? We're accepting content ideas for SAS Innovate 2025 to be held May 6-9 in Orlando, FL. The call is open until September 25. Read more here about why you should contribute and what is in it for you!
Learn how use the CAT functions in SAS to join values from multiple variables into a single value.
Find more tutorials on the SAS Users YouTube channel.