I have rather grim news for you. It can be done only partially, and without understanding the code logic it's rather "fail". Except those 3 options: mprint, mlogic, and symbolgen, mentioned by @MayurJadhav there is also one called MFILE which allow to store generated 4GL in a text file. But.. even if you decide to turn them on:
filename mprint "C:\text.txt";
options mfile mprint mlogic symbolgen;
you can easily find examples of macros which will never give you any "info" how they work... like those 3 examples:
%macro test0(dset);
%local rc Variables;
%let rc = %sysfunc(DoSubL(%str(
options nonotes nosource nomprint nosymbolgen nomlogic;
proc transpose data = &dset.(obs=0) out = _tmp(keep = _name_);
var _all_;
run;
proc sql noprint;
select _name_
into :Variables separated by " "
from _tmp;
drop table _tmp;
quit;
)));
&Variables.
%mend test0;
%macro test1()/secure;
data _null_;
put "This is top secret data step";
run;
%mend test1;
%macro test2()/secure;
%local temp_options;
%let temp_options =
%sysfunc(getoption(mprint))
%sysfunc(getoption(symbolgen))
%sysfunc(getoption(mlogic))
;
options nomprint nosymbolgen nomlogic;
data _null_;
put "This is top secret data step number 2";
run;
options &temp_options.;
%mend test2;
%put *%test0(sashelp.class)*;
%test1()
%test2()
The first one with the DoSubL() function embedded, the second with Secure option on, and the third with options turned off inside it.
Bart
