How to input value from different observation ?

[whymath]

I have some data like

1 2 3 ...

A B C ...

The first row are some numbers and the second row are the corresponding string value.

I want input them into SAS as a dataset but I just don't success. The desire output should be like:

1 A

2 B

3 C

Here is what I have tried: 

data test;
  do i = 1 to 3;
    input @(2*i-1) RANDNO #2 @(2*i-1) GROUP$;
      output;
    end;
  cards;
1 2 3
A B C
;
run;

Please help.

[Kurt_Bremser]

Do you always have two rows?

Is the number of columns fixed, or arbitrary?

And most important: is this a SAS dataset, or an external text file?

[whymath]

Thank for your reply.

1. No. there can more rows. Data looks like this:
1 2 3

A B C

4 5 6

D E F

...

2. It is fixed at 3.

3. It is read from SAS datalines, not external files.

[Kurt_Bremser]

See this:

data want;
array numval {3} _temporary_;
array charval{3} $ _temporary_;
length randno 8 groups $8;
do i = 1 to 3;
  input numval{i} @;
end;
input;
do i = 1 to 3;
  input charval{i} @;
end;
do i = 1 to 3;
  randno = numval{i};
  groups = charval{i};
  output;
end;
keep randno groups;
datalines;
1 2 3
A B C
4 5 6
D E F
;