Not even going to attempt to type in that stuff to create a data set to test code.
One clue to your problem is this bit right here:
%report_freqs(datain=aug17, date9var=01AUG2017)
%report_freqs(datain=sep17, date9var=01sep2017)
If you have values on the records, such as month and year, or an actual date value then unless your aug17 and sep17 data sets are very poorly constructed you should be able to combine the data sets and use the date value to create columns.
The second is that you have Proc freq generating output that sounds like you are manually reading things and then retyping. Proc FREQ will create output data sets.
Example follows. You should have the SASHELP.CLASS set installed.
ods output onewayfreqs=work.classfreq;
proc freq data=sashelp.class ;
tables sex age;
run;
data work.cleanerfreq;
set work.classfreq;
length rowlabel $ 20;
rowlabel=coalescec(sex, age);
run;
proc print data= work.cleanerfreq;
var rowlabel frequency cumfrequency percent cumpercent;
run;
If you run one of those proc freqs with your data sorted by date (DOS??) and a format assigning the date display as a single month, such as MO
NYY7. Then you get a count per month in the output.
This uses a data set you likely have in your install:
proc sort data=sashelp.snacks
out=work.snacks;
by date;
run;
ods output onewayfreqs=work.dayssold;
proc freq data=work.snacks;
by date;
where qtysold>0;
format date monyy7.;
tables product;
run;
proc print data=work.dayssold;
var date product frequency;
run;
The where statement selects records so that only the days with a product sale is processed for the Proc Freq. The group created by the assigned format is honored for counting and the frequency is the number of days of sales because the source data has one record per product/date
Or conversely a slightly more complex report
proc report data=work.snacks;
columns product date,( qtysold=qtyn qtysold=qtysum);
format date monyy7.;
define product /group;
define date/across;
define qtyn/ analysis n 'Days with sales';
define qtysum/ analysis sum 'Total sales';
run;
I suspect with actual data I could do a report using Proc Tabulate as well.although you really have to tell why some of your percentage values are in () and others aren't. Typically (xx%) is one way of indicating negative percentages but since Proc Freq won't create negative percentages I am confused.
