Make Format from DataSet

[PeterSchwennesen]

Hi All
I am brand new to this SAS thing. I have a question about making Formats. I have tried make a Format from a explaining, but in this Format I also like to have a "Other=" entry to mark all values outside the defined range, but I do not know how to do. This is the code; but all values go to "???" and not just the number 3 as I expected.

data t1;
input key name $;
cards;
1 A
2 B
; run;

data t2 (drop=key name);
set t1;
fmtname='fmt';
start=key;
label=name;
run;

proc format cntlin=t2;
value fmt other='???';
run;

data y;
a=3; b=2; c=1;
put a a fmt.;
put b b fmt.;
put c c fmt.;
run;

any help? or are there another post desribing how to do?

Peter Schwennesen

[Patrick]

Hi

A fast way to get the code right is to use SAS Enterprise Guide (4.3 - not sure about earlier versions).

There you find under "Tasks/Data/Create Format from Dataset..." a wizard which creates you the code.

HTH
Patrick

[data_null__]

[pre]
data t1;
input key name $;
cards;
1 A
2 B
; run;

data t2;
retain fmtname 'fmt' type 'n' hlo ' ';
length label $64;
set t1(rename=(key=start name=label)) end=eof;
output;
if eof then do;
call missing(start);
label = 'Outside Range';
hlo = 'O';
output;
end;
run;
proc format cntlin=t2 cntlout=cntlout;
run;
proc print data=cntlout;
run;
[/pre]

[PeterSchwennesen]

Hi Data_NULL_
Thanks. Now it is Working.
However it is a little cryptic code for me,
I am not Quite sure what the function of "call missing(Start); hlo='O' is.
but thanks,
Peter Schwennesen

[art297]

Peter,

DataNull was simply putting in the conditions to include an extra format record in case any of your values fall outside of the defined formats.

You'll notice that both of those statements are only run after all of the records have been read (i.e., at the end of the file).

call missing(Start) simply set the value of start to missing and hlo='O' sets the value of hlo to 'O' or 'other'

HTH,
Art
---------
> Hi Data_NULL_
> Thanks. Now it is Working.
> However it is a little cryptic code for me,
> I am not Quite sure what the function of "call
> missing(Start); hlo='O' is.
> but thanks,
> Peter Schwennesen

[PeterSchwennesen]

Hi Art
I still do not quite understand, but I hope it will com.
I get the overall meaning.
But thanks
Peter Schwennesen

[art297]

Peter,

A nice (I think) explanation of the process can be found at:
http://www2.sas.com/proceedings/sugi26/p236-26.pdf

HTH,
Art
> Hi Art
> I still do not quite understand, but I hope it will
> com.
> I get the overall meaning.
> But thanks
> Peter Schwennesen

[DrAbhijeetSafai]

Hi Peter,

Greetings!

I also had the similar question as how to create a format from a dataset. I found following two sources useful. 

1) SAS Documentation: https://documentation.sas.com/doc/en/vdmmlcdc/8.1/proc/n1e19y6lrektafn1kj6nbvhus59w.htm

 2) A paper with title "Creating a Format from Raw Data or a SAS® Dataset " by Wendi L. Wright : https://support.sas.com/resources/papers/proceedings/proceedings/forum2007/068-2007.pdf

The paper is of 2007 and in documentation, a table named 'The CTLR Dataset' gives lot of information. However, if there is any better way of understanding it, please let me know. 

Thanking you,

Yours sincerely,

- Dr. Abhijeet Safai