Generate a new variable that reverses the order of an existing variable.

[Golf]

Suppose I have  3 variables  (X, Y, and Z)

    obs   X    Y     Z

      1    10    11     21

      2     2     12   22

      3   40   13    23

      4    4    14    24

      5   80    15    25

I want to create a new variable called XX that reverses the order of variable X while preserving the order of the other variables.

    obs   X   Y     Z     XX

      1     10  11    21     80

      2      2   12   22      4

      3    40  13   23    40 

      4      4   14   24      2

      5    80   15   25    10

Could you provide guidance on how to write SAS code to generate the second data set?

Thanks

[Kurt_Bremser · Accepted solution]

Is there anything in your dataset which denotes groups?

For the dataset as posted, I'd do

data second;
set have (keep=x rename=(x=xx));
n = _n_;
run;

proc sort data=second;
by n descending;
run;

data want;
merge
  have
  second (drop=n)
;
run;

Untested, posted from my tablet.

[Golf]

Thank You so much.

[FreelanceReinh]

Alternatively, you can use a second SET statement with a POINT= option:

data want;
set have nobs=n;
_n_=n-_n_+1;
set have(keep=x rename=(x=xx)) point=_n_;
run;

[yabwon]

@FreelanceReinh, I didn't notice your solution and wrote almost exactly the same 😄 😄

Bart

[yabwon]

You can use the POINt= for this (no sorting).

data have;
input X Y Z;
cards;
10    11     21
2     12   22
40   13    23
4    14    24
80    15    25
;
run;
proc print data=have;
run;


data want;
  set have nobs=nobs curobs=curobs;
  point=nobs-curobs+1;
  set have(keep=x rename=(x=xx)) point=point;
run;

proc print data=want;
run;

Bart

[Golf]

Thank You

[Ksharp]

Just for some fun. Here is  a SAS/IML solution.

data have;
input X Y Z;
cards;
10    11     21
2     12   22
40   13    23
4    14    24
80    15    25
;
run;
proc iml;
use have nobs nobs;
read all var {x y z};
close;
xx=x[nobs:1];
create want var {x y z xx};
append;
close;
quit;

[Golf]

Thank You.