Delete negative values ( NOT '.')

[spraynardz90]

Hi I am looking to delete any observation with a negative value...

Generally I use:

data x; set x; if variable<0 then delete; run;

However this deletes blank observations such as '.' along with any negative values.

Does anyone know how to delete only negative values?

Unfortunately the statement below doesn't work:

data x; set x; if variable=- then delete; run;

[shivas · Accepted solution]

Hi,

Just try this....I am not sure this is optimized solution or not.

data one;

input nub;

cards;

-20

-10

0

.

12

;

run;

data two;

set one;

if index(nub,'-') then delete;

run;

Thanks,

Shiva

[Ksharp]

You need not missing() to judge it .

data one;

input nub;

cards;

-20

-10

0

.

12

;

run;

data two;

set one;

if nub<0 and not missing(nub) then delete;

run;

Ksharp

[SteveDenham]

How about:

data one;

input nub;

cards;

-20

-10

0

.

12

;

run;

data two;

set one;

if .<nub<0  then delete;

run;

As . is always less than any value.

Steve Denham

[data_null__]

SteveDenham wrote:

As . is always less than any value.

Are you sure?

2360  data _null_;

2361     x = . min ._;

2362     put x=;

2363     run;

x=_

[SteveDenham]

How about ". is always less than any value on the real line (-∞,∞)" ?

And I learned something new about the underscore--I always thought it to be a character only.

Thanks!

Steve Denham

[data_null__]

It is a special missing value not character underscore.

[SteveDenham]

So I would assume (mmmm danger), that the same would apply for .A .B thru to .Z--the numeric missing codes?

Steve Denham

[data_null__]

The same what?

[SteveDenham]

We're now out of sync.  See Hai.Kuo's post with the link to the order of missing values.  That clarifies everything, and should satisfy the OP's question.

Since I have almost no need to use the "coded" missing values, I made the mistake of thinking that .A thru .Z were the equivalent of ._ for ordering (i.e. "the same").

Learned a lot this morning.

Steve Denham

[Haikuo]

See, this is exactly the reason I would never want to miss your post. Thanks!

Haikuo

[Haikuo]

Using the information from following link to construct your comparison:

http://support.sas.com/documentation/cdl/en/lrcon/62955/HTML/default/viewer.htm#a000989180.htm

Haikuo

[SteveDenham]

A-HA!

That was the link I was looking for this morning.

So the .A thru .Z missing values are GREATER THAN .

Thanks Hai.kuo!

Steve Denham

[data_null__]

According to this link ._ is not special missing value.  I have always called it a special missing value.

[Howles]

Try

   if sign(variable) EQ -1 then delete ;

See

   http://www.sascommunity.org/wiki/Numeric_transformations

spraynardz90 wrote:

Hi I am looking to delete any observation with a negative value...
Generally I use:

data x; set x; if variable<0 then delete; run;

However this deletes blank observations such as '.' along with any negative values.

Does anyone know how to delete only negative values?

Unfortunately the statement below doesn't work:

data x; set x; if variable=- then delete; run;