First of all , it is NOT a question for a help.
Last night, I watched an intesting vedio .
A magician hold a black package in which there are 24 balls, 8 is red, 8 is blue, 8 is yellow.
He asked an audience to pull out 12 balls from his black package.
If the color balls conform to 3:4:5 ,then audience should pay him 10 dollars .
If it was others, he pay this audience 10 dollars .
The intesting thing happened, most of audience obtained 3:4:5 ,and this magician earn many money.
Why? In general, I would expect that probability should be 4:4:4 ,since it was randomly picked up .
Just to confirm this result , I wrote some IML code to simulate many times to see how the proability distributed. This code is motivated by @Rick_SAS blog(which conform to Hypergeometric distribution):
https://blogs.sas.com/content/iml/2015/09/30/balls-and-urns1.html
https://blogs.sas.com/content/iml/2015/10/14/sim-2x2-model.html
proc iml;
call randseed(123);
/* simulate 1000000 times */
n=1000000;
want=j(n,3,.);
do i=1 to n;
/*24 balls in the black package.8 is red,8 is blue,8 is yellow*/
expect={8 8 8}; sum=sum(expect);
/*pull out 12 balls*/
want_sum=12;
/*get the red balls*/
if want_sum=0 then want[i,1]=0;
else do;
call randgen(x, "Hyper", sum, expect[1], want_sum);
want[i,1]= x;
sum=sum-expect[1];
want_sum=want_sum-x;
end;
/*get the blue balls*/
if want_sum=0 then want[i,2]=0;
else do;
call randgen(x, "Hyper", sum, expect[2], want_sum);
want[i,2]= x;
sum=sum-expect[2];
want_sum=want_sum-x;
end;
/*get the yellow balls*/
if want_sum=0 then want[i,3]=0;
else do;
call randgen(x, "Hyper", sum, expect[3], want_sum);
want[i,3]= x;
sum=sum-expect[3];
want_sum=want_sum-x;
end;
end;
create want from want;
append from want;
close;
quit;
data want2;
set want;
length flag $ 8;
call sort(of _numeric_);
flag=catx(':',of _numeric_);
run;
proc freq data=want2 order=freq;
table flag/plots=freqplot(orient=horizontal scale=percent);
run;
After simulating one million times , I got this graph. You can see 3:4:5 occurred almost 50 percent ,that is a big huge hit.
Accepted Solutions
Just to be clear: probability is not my super-power but:
Ain't that case of multivariate hypergeometric distribution?
https://en.wikipedia.org/wiki/Hypergeometric_distribution#Multivariate_hypergeometric_distribution
and the fact that:
P(3,4,5) is independent from P(3,5,4), etc,
P(3,4,5 or 3,5,4) = P(3,4,5) + P(3,5,4) - P(3,4,5 and 3,5,4) = P(3,4,5) + P(3,5,4)
so probability P("I have 3:4:5 sequence") would be just sum of P(3,4,5) + P(3,5,4) + ...+ P(5,4,3).
data have;
input grp $ r g b;
cards;
a 4 4 4
b 3 4 5
b 3 5 4
b 4 3 5
b 4 5 3
b 5 3 4
b 5 4 3
;
run;
/*
a = get all 4
b = get 3:4:5
*/
data want;
rn=8;
gn=8;
bn=8;
N=rn+gn+bn;
set have;
k=r+g+b;
p = /* https://en.wikipedia.org/wiki/Hypergeometric_distribution#Multivariate_hypergeometric_distribution */
(comb(rn, r)
*comb(gn, g)
*comb(bn, b)
)
/comb(n, k)
;
put (_ALL_) (=/);
if _N_=2 then sum=0;
sum+p;
run;
proc print;
run;
[EDIT:] proc print:
Bart
Here I would like to use PROC SURVEYSELECT to mimic SAMPLE() funtion in SAS/IML for sombody was not familiar with IML syntax.
data have;
do i=1 to 8;
ball='Y';output;
ball='B';output;
ball='R';output;
end;
drop i;
run;
proc surveyselect data=have out=temp seed=123 sampsize=12 reps=1000000;
run;
proc freq data=temp noprint;
table Replicate*ball/out=temp2 sparse list;
run;
proc sort data=temp2;
by Replicate count;
run;
data want;
length flag $ 8;
do until(last.Replicate);
set temp2;
by Replicate;
flag=catx(':',flag,count);
end;
keep Replicate flag;
run;
proc freq data=want order=freq;
table flag/plots=freqplot(orient=horizontal scale=percent);
run;
