Remove "(continued)" string from report when using ODS TAGSETS.RTF

[deleted_user]

Hi,

When using ODS TAGSETS.RTF I get a default string "(continued)" when my table splits across pages. Is there a way to remove this string?

Appreciate your help in advance.

Thanks!

[JackHamilton]

You didn't say how you are creating the output. If you're using PROC TABULATE, use the NOCONTINUED option in the TABLE statement.

[deleted_user]

I am using Proc Report.

[wayne_sas]

The best way to remove the contined tag is to modify the style element associated with it with proc template and apply the style.

Style Continued from Continued /
...
pretext = text("continued")
...
;

Set the pretext to a null string.

[deleted_user]

Thanks Wayne! making pretext=" " worked, but I also want to get rid of solid box from the report.

Currently, for the report I have rules=all and bordercolor=gray, but there is a solid black box for "Continued" string. Can we get rid of this?

Also, I appreciate if you can direct to the section in documentation where I can find this information.

Thanks again.

[wayne_sas]

I can't say where teh borders are coming from without looking at the style, but youcan override them in the same proc template with :

style continued from continued /
pretext = text(" ")
borderwidth=0pt ;

0 width drops the borders.

You could also write a short tagset whose parent is tagsets.rtf. Your tagset would just re-write the continue event to put things in a bit bucket. Something like :

define event continue ;
Notes "Continue sets flag to capture information for the continued tag" ;
start:
unset $$citydump_tbl;
set $current_tbl "citydump_tbl" ;

finish:
unset $current_tbl ;
end;

[Cynthia_sas]

Hi:
When I try this, I get the (Continued) on the first output file, but if I use the new template for the second output, I do not see any boxes or lines. I don't think a tagset change is needed, just a style template change.

cynthia
[pre]
ods path work.ctest(update)
sasuser.templat(update)
sashelp.tmplmst(read);


proc template;
define style styles.nocontin;
parent=styles.rtf;
class text /
'continued' = " ";
class Continued /
frame=void
pretext = _undef_
borderspacing = 0
padding = 0 ;
end;
run;

options nodate;
ods tagsets.rtf file='twopage.rtf' ;
title 'default style -- with Continued';
proc print data=sashelp.shoes(obs=60);
var region product sales inventory;
run;
ods tagsets.rtf close;

ods tagsets.rtf file='nocontin.rtf' style=nocontin;
title 'New style -- no continued';
proc print data=sashelp.shoes(obs=60);
var region product sales inventory;
run;
ods tagsets.rtf close;

title;
[/pre]

[deleted_user]

Thanks Wayne and Cynthia for your replies.

Cynthia, I tried your solution as it was easy to change style template. After adding your style code I still see a box at the bottom of the report, I added bordercolor=white but this did'nt work either.

I did'nt tried writing a tagset as Wayne suggested as I am still not comfortable understanding TAGSETS.

Do you have any other solution to make this box disappear?

Thanks for your time!

[Cynthia_sas]

Hi, Cyrus:
When I test the code in 9.2, with TAGSETS.RTF, I do NOT see a box around the empty place where "continued" formerly appeared. The first TAGSETS.RTF invocation shows the default behavior and the second TAGSETS.RTF invocation uses the new template.

If you are getting different results in SAS 9.2 using TAGSETS.RTF, then I suggest you open a ticket with Tech Support. I am not seeing your behavior in my install of SAS 9.2 with the above template code.

cynthia

[SuzanneDorinski]

Sorry to jump in relatively late here. I was wondering how to get rid of the "(Continued)" at the bottom of the table that splits across pages. The style template change that Cynthia suggests works well. (Thanks!)

When I open the file in Word in Print Layout view, the default is to show table gridlines, and there is an empty table at the bottom of the page when you have gridlines showing. If you choose to Hide Gridlines from the Table menu, the gridlines disappear. I'm using Word 2000 at work, so I can't remember off the top of my head how to hide the gridlines in Word 2007.

The gridlines themselves don't show up when you print the page.

[sbb]

Suggest you open a new thread since that is what your question is about -- it's quite normal to do so and include a link to past threads/posts, where relevant. To piggy-back on some other individual's original post is not recommended.

Scott Barry
SBBWorks, Inc.

[SuzanneDorinski]

Actually, the original poster wanted to know how to get rid of the box that he was seeing in the output after he used Cynthia's solution. I was trying to point out that what he is seeing is probably table gridlines in Word, because that box is actually a table. My apologies if I wasn't clear enough in my response.

[Andre]

Cynthia,
something is not clear in the template code as it was rejected in 9.1.3


6 proc template;
7 define style styles.nocontin;
8 parent=styles.rtf;
9 class text /
-----
180
ERROR 180-322: Statement is not valid or it is used out of proper order.

10 'continued' = " ";
11 class Continued /
-----
180
ERROR 180-322: Statement is not valid or it is used out of proper order.
12 frame=void
13 pretext = _undef_
14 borderspacing = 0
15 padding = 0 ;
16 end;
WARNING: Object will not be saved.
17 run;

and a lot of warnings later in both tests are appearing
WARNING: In Event: populate, Invalid Expression: trigger add_footnotes /breakif $footer_flag EQ 1
WARNING: In Event: row, Invalid Expression: eval $linesleft $linesleft +1

Has all this a reference to 9.2 only?
Andre

[Cynthia_sas]

Hi, Andre:
Style template syntax changed significantly in SAS 9.2 versus the old syntax in SAS 9.1.3. I would not expect my style template code to work at all in SAS 9.1.3 -- I used 9.2 syntax because TAGSETS.RTF is production in SAS 9.2. Therefore, the style template should match the version of SAS being used.

I know that there was a "pre-production" TAGSETS.RTF in SAS 9.1.3, but most times when I tried it, my instance of SAS crashed. So I never used it.

The CLASS statement is new Style template syntax for SAS 9.2. It's very cool because it allows you to write a style template without worrying about inheritance. The CLASS statement allows the named style element to inherit attributes from a like named style element in the parent template. There was no CLASS statement in SAS 9.1.3 and inheritance actually worked/works differently in 9.1.3 (where you have to choose between the STYLE or REPLACE statement) and 9.2 (where you don't have to worry about how you code your style element), where these are all equivalent statements:
style text from text / ...
style text from _self_ / ...
style text / ...
class text / ...

Sorry it didn't work. I should have been more explicit that it was 9.2 code.

cynthia