Is it possible to include sequentially numbered titles for plots?

[samp945]

Hello all,

I am using by group processing to create a number of separate plots. SAS creates sequentially numbered file names with ODS listing and ODS graphics statements. I can also create dynamic titles according to the by group by following the tips from a great blog post.

However, I am required to title each plot with a sequential number (e.g., Figure 2.01: Example Title#1; Figure 2.02: Example Title#2, etc.). Is there some way to create sequentially numbered titles when using by group processing? I have tried searching for relevant keywords with no luck.

Thanks for reading!

[Ksharp · Accepted solution]

Why not create a GROUP variable in which there are 1,2,3 series number and using the skill you refered to ?

proc sort data=sashelp.class out=temp;
by age weight;
run;
data temp;
set temp;
by age;
n+first.age;
run;
option nobyline;
title "Title##byval1";
proc sgplot data=temp;
by n;
series x=weight y=height;
run;

[samp945]

Very clever! I am able to use both #ByVal1 (the main by group category name) and #ByVal2 (the figure number) in the plot title.

I am already familiar with first.variable and last.variable, but can you point me toward documentation for the N+ strategy you used? I don't know what it is called or quite understand how it would be used in other applications.

[Ksharp]

Here
n+first.age;
is the identity with
if first.age then n+1;

[samp945]

Thanks! What if I would like to begin the numbering at a specific number instead of 1? For example, if I want "n" to begin at 8?
run;

[Ksharp]

Give it an initial value 7 by RETAIN statement, as the URL posted by Tom.

data temp;
set temp;
by age;
retain n 7;
n+first.age;
run;

[Tom]

That is a SUM statement.

https://documentation.sas.com/doc/en/pgmsascdc/9.4_3.5/lestmtsref/n1dfiqj146yi2cn1maeju9wo7ijs.htm