BookmarkSubscribeRSS Feed
🔒 This topic is solved and locked. Need further help from the community? Please sign in and ask a new question.
cbt2119
Obsidian | Level 7

Hi SAS Community,

 

I only have SAS 9.4 TS1M4 and I'm trying to add the summary statistics to each panel, namely "N" and "Mean". I would like to do what the plot option DISPLAYSTATS does in TS1M5, but I'm having difficulty. I found a Graphically Speaking blog post showing how to do this in SGPLOT, but is there a way to do it with SGPANEL?

 

Here is my code:

 

Title1 'Mean HIV TNA PCR Ct Values by Category of Age Started ART'; 
Title2 'Categorized by Cohort';
proc sgpanel data=merged1;
	where hivpcrct ne 0 ;
	panelby cohort / rows=4 onepanel uniscale=column;
	vbox hivpcrct / category = artstartcat ;
	colaxis grid offsetmin=0.10 fitpolicy=rotatethin
	VALUEATTRS=(Family=Times Size=10);
	format cohort cohortf. artstartcat artstartcatf.;
	RUN;title;

I want my plot to print the N and mean for each category of Age Started ART (artstartcat). I can use the "DATALABEL" plot option in VBAR, but not in VBOX. 

 

Any help is appreciated!

 

Thanks,

Cara

1 ACCEPTED SOLUTION

Accepted Solutions
Jay54
Meteorite | Level 14

 

As you say, the feature to add the statistics table to VBOX for SGPANEL was added in SAS 9.40M5.  The option uses the values already computed for the box plot.  To do the same with a prior SAS 9.4 release, you can use the ColAxisTable.  But, you will have to compute the statistics yourself using PROC MEANS and merge it into the data as shown below.

 

/*--Compute statistics by Type and Origin--*/
proc means data=sashelp.cars;
  class type origin;
  var horsepower;
  output out=stat(where=(_type_ > 2))
    mean=Mean N=N;
run;
proc print;run;

/*--Merge statistics with original data set--*/
data cars;
  keep type origin horsepower mean n;
  set sashelp.cars stat;
run;
proc print;run;

/*--Render VBox and statistics using ColAxisTable--*/
proc sgpanel data=cars;
  panelby type;
  vbox horsepower / category=origin;
  colaxistable n mean;
run;

VBox_Stat_Panel.png

View solution in original post

2 REPLIES 2
Jay54
Meteorite | Level 14

 

As you say, the feature to add the statistics table to VBOX for SGPANEL was added in SAS 9.40M5.  The option uses the values already computed for the box plot.  To do the same with a prior SAS 9.4 release, you can use the ColAxisTable.  But, you will have to compute the statistics yourself using PROC MEANS and merge it into the data as shown below.

 

/*--Compute statistics by Type and Origin--*/
proc means data=sashelp.cars;
  class type origin;
  var horsepower;
  output out=stat(where=(_type_ > 2))
    mean=Mean N=N;
run;
proc print;run;

/*--Merge statistics with original data set--*/
data cars;
  keep type origin horsepower mean n;
  set sashelp.cars stat;
run;
proc print;run;

/*--Render VBox and statistics using ColAxisTable--*/
proc sgpanel data=cars;
  panelby type;
  vbox horsepower / category=origin;
  colaxistable n mean;
run;

VBox_Stat_Panel.png

cbt2119
Obsidian | Level 7

Thank you! This works nicely.

 

 

sas-innovate-2024.png

Don't miss out on SAS Innovate - Register now for the FREE Livestream!

Can't make it to Vegas? No problem! Watch our general sessions LIVE or on-demand starting April 17th. Hear from SAS execs, best-selling author Adam Grant, Hot Ones host Sean Evans, top tech journalist Kara Swisher, AI expert Cassie Kozyrkov, and the mind-blowing dance crew iLuminate! Plus, get access to over 20 breakout sessions.

 

Register now!

How to Concatenate Values

Learn how use the CAT functions in SAS to join values from multiple variables into a single value.

Find more tutorials on the SAS Users YouTube channel.

Click image to register for webinarClick image to register for webinar

Classroom Training Available!

Select SAS Training centers are offering in-person courses. View upcoming courses for:

View all other training opportunities.

Discussion stats
  • 2 replies
  • 3307 views
  • 1 like
  • 2 in conversation