Hi:
The code below produced this example of doing an indent in RTF using 2 different style attribute methods:
Then there are several examples of how to make the text in a cell wrap by altering the cellwidth. Since the OP did not post any data, I made some fake data, but I varied the width for the variable et_3 so that the impact could be observed at varying widths.
cynthia
** all the code;
**make some fake data;
data makelong;
length et_3 $254;
et_1 = 'aaa';
et_2 = 'bbbbbbbbbbbbbbbbbbbbbb';
tmp = 'xxxxxxxxx xxxxxxxxx xxxxxxxxx xxxxxxxxx xxxxxxxxx ';
et_3 = tmp || tmp || tmp || tmp ||tmp || tmp;
output;
output;
et_1 = 'ccc';
et_2 = 'ddddddddddd';
et_3 = translate(et_3,'w', 'x');
output;
output;
et_1 = 'eee';
et_2 = 'fffffffffff';
et_3 = translate(et_3,'f', 'w');
output;
output;
et_1 = 'ggg';
et_2 = 'hhhhhhhhhh';
et_3 = translate(et_3,'y', 'f');
output;
output;
run;
options orientation=portrait topmargin=.25in bottommargin=.25in leftmargin=.25in rightmargin=.25in;
ods escapechar='^';
ods rtf file='c:\temp\wrapit.rtf';
proc report data=makelong nowd;
title '1) Let ODS decide the default Width for et_3';
column et_1 et_2 et_3;
define et_1 /order;
define et_2 /order;
define et_3 / display;
run;
proc report data=makelong nowd;
title '2) Use CELLWIDTH attribute at 2 inches';
column et_1 et_2 et_3;
define et_1 /order;
define et_2 /order;
define et_3 / display
style(column)={cellwidth=2in};
run;
proc report data=makelong nowd;
title '3) Use CELLWIDTH attribute at 4 inches';
column et_1 et_2 et_3;
define et_1 /order;
define et_2 /order;
define et_3 / display
style(column)={cellwidth=4in};
run;
proc report data=makelong nowd;
title '4a) Use CELLWIDTH attribute at 6 inches';
column et_1 et_2 et_3;
define et_1 /order;
define et_2 /order;
define et_3 / display
style(column)={cellwidth=6in};
run;
proc report data=makelong nowd;
title '4b) Use CELLWIDTH attribute at 6 inches with smaller font for et_ variables';
column et_1 et_2 et_3;
define et_1 /order style(column)={cellwidth=.75in font_size=12pt};
define et_2 /order style(column)={cellwidth=.75in font_size=10pt};
define et_3 / display
style(column)={cellwidth=6in font_size=8pt};
run;
ods rtf close;title;
ods rtf file='c:\temp\show_indent.rtf';
proc report data=sashelp.class;
where substr(name,1,1) le 'J';
title '5) How to indent';
column name age sex height weight;
define name / style(column)={just=l cellwidth=1in};
define sex / style(column)={just=l cellwidth=1in};
compute name;
if name in ('Barbara', 'Janet') then do;
call define(_col_,'style','style={indent=20 background=lightgreen}');
end;
endcomp;
compute sex;
if name in ('Barbara', 'Janet') then do;
call define(_col_,'style','style={leftmargin=.25in background=lightgreen}');
end;
endcomp;
run;
ods rtf close;
... View more