Since I'm closing down SAS and this was still open, this is how those were created. Feel free to ignore if it's not helpful.
/* 1. transpose from wide (Y, X1 ,...,X100) to long (varNum VarName Y Value) */
data Long;
set sashelp.cars; /* <== specify data set name HERE */
array x [*] msrp enginesize horsepower;; /* <== specify explanatory variables HERE */
do varNum = 1 to dim(x);
VarName = vname(x[varNum]); /* variable name in char var */
Value = x[varNum]; /* value for each variable for each obs */
output;
end;
keep invoice varN: value;
run;
/* 2. Sort by BY-group variable */
proc sort data=Long; by VarName; run;
ods pdf file='c:\_localdata\temp\Reg results.pdf';
ods output parameterEstimates=Pe fitstatistics=fe;
proc reg data=long;
by varName;
model invoice = value;
output out=reg_out p=predicted r=residual;
run;
ods pdf close;
ods pdf file='C:\_localdata\temp\Summary Tables.pdf';
proc print data=PE;
proc print data=FE;
run;
ods pdf close;
ods pdf file='C:\_localdata\temp\Graphs.pdf';
proc sgplot data=reg_out;
by varName;
scatter x=value y=invoice;
scatter x=value y=predicted;
run;
ods pdf close;
... View more
