Sure, here is my code for the report: options papersize='LETTER' orientation=landscape topmargin='2.54cm'
bottommargin='2.54cm' leftmargin='2.54cm' rightmargin='2.54cm' nodate nonumber
missing=' ';
%** Create template for TLFs **;
proc template;
%** Courier 9pt **;
define style styles.ods_9pt;
parent=styles.rtf;
replace fonts/ 'TitleFont2'=("Courier New", 9pt) 'TitleFont'=("Courier New",
9pt) 'FootnoteFont'=("Courier New", 9pt) 'StrongFont'=("Courier New", 9pt)
'EmphasisFont'=("Courier New", 9pt) 'FixedEmphasisFont'=("Courier New", 9pt)
'FixedStrongFont'=("Courier New", 9pt) 'FixedHeadingFont'=("Courier New",
9pt) 'BatchFixedFont'=("Courier New", 9pt) 'FixedFont'=("Courier New", 9pt)
'headingEmphasisFont'=("Courier New", 9pt) 'headingFont'=("Courier New",
9pt) 'docFont'=("Courier New", 9pt);
replace document from container / asis=on protectspecialchars=off;
replace SystemFooter from TitlesAndFooters / asis=on protectspecialchars=on
font=Fonts('FootnoteFont');
replace systemtitle from titlesandfooters/ asis=on protectspecialchars=off;
replace body from document / asis=on;
replace color_list "Colors used in the default style" / 'link'=blue
'bgH'=white 'fg'=black 'bg'=white;
replace Table from output / Background=_UNDEF_ cellpadding=0pt Rules=groups
Frame=hsides;
style Header from Header / Background=_undef_;
style Rowheader from Rowheader / Background=_undef_;
replace pageno from titlesandfooters/ Foreground=white;
end;
run;
ods rtf file='/home/u63366981/01_adam/results/tableae.rtf' style=styles.ods_9pt;
ods rtf startpage=now;
ods escapechar='#';
%let current_date = %sysfunc(date(), yymmdd10.);
%let current_time = %sysfunc(time(), time5.);
title1 color="black" justify=left "Protocol:CDISCPILOT01" justify=right 'Page #{thispage} of #{lastpage}';
title2 color="black" justify=left "Population:Safety" justify=right "Date: ¤t_date. ¤t_time.";
title3 color="black" justify=center bold "Template 13";
title4 color="black" justify=center
"Incident of Treatment Emergent Adverse Events by Treatment Group";
options center number;
proc report data=final2 nowindows nowd headline headskip split='*'
out=finalreport;
column (aeterm ("Placebo (N=&bign1.)" trt1 tot1)
("Xanomeline High*Dose (N=&bign2.)" trt2 tot2)
("Xanomeline Low*Dose (N=&bign3.)" trt3 tot3) (z1) (z2));
define aeterm/'System Organ Class * PREFERRED TERM' left;
define trt1/'n (%)' style(column)=[cellwidth=1in] left;
define tot1/'Total*Events' center;
define trt2/'n (%)' style(column)=[cellwidth=1in] left;
define tot2/'Total*Events' center;
define trt3/'n (%)' style(column)=[cellwidth=1in] left;
define tot3/'Total*Events' center;
define z1/'Placebo vs. Xan. Low Dose p-value' style(column)=[cellwidth=0.5in]
center;
define z2/'Placebo vs. Xan. High Dose p-value' style(column)=[cellwidth=0.5in] center;
footnote1 justify=left "Treatment emergent events are defined as events which start or worsen or recur on or after the start of treatment.";
footnote2 justify=left "Adverse events are coded using MedDRA.";
footnote3 justify=left "Percentages are based on the number of subjects in the safety population within each treatment group.";
footnote4 justify=left "P-values are based on Fisher's Exact test for the comparison of placebo versus each active treatment group.";
footnote5 justify=left "Total Events represent the total number of times an event was recorded within each treatment group.";
run;
ods rtf close;
... View more