> As you said, subtraction can not achieve the purpose.
I did not say that. I said that you SHOULD use subtraction if theta represents a threshold parameter and you are setting the threshold value.
Here is a link to the PROC FMM documentation that discusses the Weibull function. The doc explicitly states that FMM fits a two-parameter model. There is no theta parameter, so you cannot specify theta on the RESTRICT statement.
You can tell from the doc that the FMM procedure fits the multiplicative inverse of the SCALE parameter that UNIVARIATE fits. That is, if PROC UNIVARIATE estimates (Sigma, C), you can get similar estimates from PROC FMM. The relation is
Sigma = exp(Intercept)
C = 1/Scale
where Intercept and Scale are the parameter estimates from PROC FMM.
Here is an example program that uses simulated data and fits by using PROC UNIVARIATE and PROC FMM:
data All;
call streaminit(123);
theta=5;
component = 1;
do i = 1 to 2000;
d = theta + rand("weibull", 1.5, 0.8); /* C=Shape=1.5; Sigma=Scale=0.8 */
output;
end;
component = 2;
do i = 1 to 1000;
d = theta + rand("weibull", 4, 2); /* C=Shape=4; Sigma=Scale=2 */
output;
end;
run;
proc univariate data=All;
class component;
var d;
histogram d / weibull(theta=5); /* fit (Sigma, C) for each component */
ods select ParameterEstimates;
run;
data W;
set All;
d = d - 5; /* subtract the known value of the theta parameter */
run;
/* in parameter estimate table,
- the "Inverse Linked Estimate" = exp(Intercept) is the Sigma
param from UNIVARIATE
- the Scale estimate is 1/C, where C is the parameter from UNIVARIATE
*/
proc fmm data=W plots=density;
model d = / dist=weibull link=log k=2;
ods select ParameterEstimates MixingProbs DensityPlot;
run;
Compare the results from UNIVARIATE and FMM. I believe this program answers all your questions.
