Yes, you can get the bootstrap CLM at each value of the explanatory variable.
First, read about how to perform case resampling in the blog post "Bootstrap regression estimates: Case resampling":
Then, you can read about how to obtain bootstrap estimates of the CLM in the blog post "Bootstrap confidence intervals for the predicted mean in a regression model"
For completeness, the following program implements the bootstrap method to estimate the CLM at a set of points that you can specify:
/* choose data to analyze. Optionally, sort. */
data Sample(keep=x y);
/* rename vars to X and Y to make roles easier to understand */
set Sashelp.Class(rename=(Weight=Y Height=X));
run;
/* OPTIONAL: Sort by X variable for future plotting */
proc sort data=Sample; by X; run;
/* create a scoring set */
data ScoreData;
do X = 50 to 75 by 5;
ScoreId + 1; /* include an ID variable */
output;
end;
run;
/* 1. Compute the statistics on the original data. Estimate CLM by using the asymptotic formula.
Concatenate the scoring data and use the "missing response trick"
https://blogs.sas.com/content/iml/2014/02/17/the-missing-value-trick-for-scoring-a-regression-model.html
*/
data SampleAndScore;
set Sample ScoreData(in=S);
IsScore = S;
run;
proc reg data=SampleAndScore plots(only)=FitPlot(nocli);
model Y = X;
/* output the theoretical CI for each scoring observation for later comparison */
output out=RegOut(where=(IsScore=1)) Pred=Pred LCLM=LowerP UCLM=UpperP;
run; quit;
/* 2. Generate many bootstrap samples by using PROC SURVEYSELECT */
%let NumSamples = 5000; /* number of bootstrap resamples */
proc surveyselect data=Sample NOPRINT seed=1
out=BootCases(rename=(Replicate=SampleID))
method=urs /* resample with replacement */
samprate=1 /* each bootstrap sample has N observations */
/* OUTHITS (optional) use OUTHITS option to suppress the frequency var */
reps=&NumSamples; /* generate NumSamples bootstrap resamples */
run;
/* 3. Compute the statistics for each bootstrap sample. */
proc reg data=BootCases outest=PE noprint; /* fit the model and save the parameter estimates for each sample */
by SampleID;
freq NumberHits;
model Y = X;
run;quit;
proc score data=ScoreData score=PE type=parms predict /* score each model on the scoring data */
out=BootOut(rename=(MODEL1=Pred));
by SampleID;
var X;
run;
/* 4. Compute the bootstrap 95% prediction CL for each row in the score data */
/* Find the 2.5th and 97.5th percentiles for the bootstrap statistics each X value */
proc univariate data=BootOut noprint;
class ScoreID;
var Pred;
output out=BootCL mean=BootMean pctlpre=Pctl_ pctlpts=2.5, 97.5;
run;
/* merge the REG output and the bootstrap CL */
data All;
merge RegOut BootCL;
by ScoreID;
run;
proc print data=All;
var ScoreId X BootMean Pctl_2_5 Pctl_97_5;
run;
/* visualize the bootstrap mean and CLM */
title "Bootstrap CLM";
title2 "&NumSamples Bootstrap Samples";
proc sgplot data=All;
series x=x y=Pred / legendlabel="OLS Pred" lineattrs=(color=gray);
scatter x=x y=BootMean / legendlabel="Boot Pred" markerattrs=(symbol=X);
highlow x=x low=Pctl_2_5 high=Pctl_97_5 / legendlabel="Boot CLM"
lowcap=serif highcap=serif lineattrs=GraphError;
yaxis label="Y";
run;
