SAS GENMOD: How To Specify A Negative Inverse Link For Gamma Distribution

[MigMaster12]

Hello all,

I was wondering how to specify the gamma distribution's canonical negative inverse link in the PROC GENMOD procedure.

When I tried leaving "LINK" blank, I saw that SAS automatically implemented a POWER(-1) link. However, to my understanding, that is akin to the inverse, and not a negative inverse link.

Any help would be greatly appreciated!

[unison]

(Data source: https://www.stat.ncsu.edu/people/davidian/courses/st732/examples/ex11_3.sas)

Define a custom fwdlink and invlink:

data clots;
input u y;
x=log(u);
datalines;
5 118 
10  58 
15  42 
20  35 
30  27 
40  25 
60  21 
80  19 
100 18
;
run;

*default POWER(-1);
proc genmod data=clots;
   model y = x / dist=gamma
   				 link = POWER(-1);
   output out       = Residuals
          pred      = Pred;
run;

*user-defined -POWER(-1);
proc genmod data=clots;
   model y = x / dist=gamma;
   fwdlink link = -1*_MEAN_**-1;
   invlink ilink = -1*_XBETA_**-1;
   output out       = Residuals
          pred      = Pred;
run;

Take a look at the parameter estimates!

-unison