Pooled estimate for interaction term in PROC MIANALYZE using PROC PHREG

[Seth10]

I imputed some survival data and want to get a pooled estimate for the interaction term included in the following model. The PROC PHREG model runs fine, and the interaction is statistically significant. The PROC MIANALYZE runs perfectly fine without the interaction term included. When I run the PROC MIANALYZE with the interaction term, it draws the following error: 

"ERROR: The model effect derived with the specified CLASS statement, new_surgery1*timetrying, is not in the PARMS= data set. One likely reason is the variable ordering in the CLASS statement is not the same as the specified CLASS variable ordering in the procedure that creates the data set."

I have confirmed that the variable ordering in the CLASS statement is the same. How can I get a pooled estimate for the interaction term? Here is my code:

proc phreg data = mi;
class new_surgery1 (ref = "0") timetrying (ref = "0") prevpreg_cl (ref="1") prev_treat (ref="0")/PARAM=REF;
model (start1,stop1)*censored(1) = new_surgery1 timetrying prevpreg_cl prev_treat new_age_at_consent new_surgery1*timetrying/ ties=efron rl;
by _imputation_;
ods output ParameterEstimates=a_preg;
HAZARDRATIO NEW_SURGERY1;
run;

proc mianalyze parms(classvar=ClassVal)=a_preg;
class new_surgery1 timetrying prevpreg_cl prev_treat;
modeleffects new_surgery1 timetrying prevpreg_cl prev_treat new_age_at_consent TIMETRYING*NEW_SURGERY1;
run;

Thanks!

[SteveDenham]

Could it be as simple as the variable is called "new_surgery1*timetrying" in the MODEL statement for PHREG, but is called "TIMETRYING*NEW_SURGERY1" in the MODELEFFECTS statement for MIANALYZE? MIANALYZE can be picky about things like the variables not having identical names (including case on occastion).

SteveDenham

[Seth10 · Accepted solution]

Thanks for your response! 

I actually just discovered in the output dataset that SAS shortened the interaction name to timetryin*new_surgery1. I included the new name in the PROC MIANALYZE and it worked. 

[SAS_Rob]

You could also use the NAMELEN= option on the PHREG statement to keep it from truncating the names of the effects.