Regular expressions are for pattern matching but it appears you are after exact matches. You could create and use a format for such a case as demonstrated in below code.
/* list of desired icd codes */
data want_codes;
input icd_code:$9.;
datalines;
F060
F061
F062
F0630
F0631
F0632
F0633
;
/* prepare data to create format from the desired code list */
data fmt_source;
retain fmtname '$ICD_MATCH' type 'C' default 1;
set want_codes(rename=(icd_code=start)) end=last;
label=1;
output;
if last then
do;
label='0';
hlo='O';
output;
end;
run;
/* create format $ICD_MATCH */
proc format cntlin=fmt_source;
run;
/* use format to determine if icd code is in the desired list */
data demo;
input icd_code:$9.;
selection_flg=put(icd_code,$icd_match.);
datalines;
F0630
F0631
F999
F0731
;
proc print data=demo;
run;
Should you need to find such matching codes in a free text field then you could use a regular expression to extract the terms that could be an icd code and then use above approach to determine if the term matches to any of the codes in your desired list.
