How to change the starting time point of Kaplan plot - Proc lifetest?

[Medidata]

Hello,

I am a layman SAS user. Can anyone please tell me how I change the starting point of a Kaplan graph? For example, I want to start directly from 10 months onward.



Like in this graph I only need 10 months onward to 60. How do I exclude a timeline from 0 to 10?

I am using this statement [proc lifetest data=WORK.CS notable plots=survival (atrisk(maxlen=13)=0 to 60 by 12) MAXTIME=60;
time 'Survival months'n*'Vital status'n(1);
Strata Gender;
run;}

Is there any simple plain statement like MAXIME limiting the ending point?

[sbxkoenk]

Hello,

Not sure whether it's possible in a very easy way (like using a simple option in PROC LIFETEST).

If not, you can definitely change the (outlook of the) plot the way you want the "hard" way.

• SAS/STAT® 15.1 User’s Guide
  Customizing the Kaplan-Meier Survival Plot
  https://support.sas.com/documentation/onlinedoc/stat/151/kaplan.pdf
• Paper 427-2013
  Creating and Customizing the Kaplan-Meier Survival Plot in PROC LIFETEST
  Warren F. Kuhfeld and Ying So, SAS Institute Inc.
  https://support.sas.com/resources/papers/proceedings13/427-2013.pdf
• Paper SP14–SAS-2014
  Creating and Customizing the Kaplan-Meier Survival Plot in PROC LIFETEST in the SAS/STAT® 13.1 Release
  Warren F. Kuhfeld and Ying So, SAS Institute Inc.
  https://www.lexjansen.com/pharmasug/2014/SP/PharmaSUG-2014-SP14-SAS.pdf
• Creating and customizing the Kaplan-Meier Survival Plot in PROC LIFETEST
  https://video.sas.com/detail/video/2918155168001/creating-and-customizing-the-kaplan-meier-survival-...
• MWSUG 2014 - Paper AA08
  Kaplan-Meier Survival Plotting Macro %NEWSURV
  Jeffrey Meyers, Mayo Clinic, Rochester, Minnesota
  https://www.mwsug.org/proceedings/2014/AA/MWSUG-2014-AA08.pdf

Koen

[Ksharp]

/*
I think there is NOT any simple plain statement to get this
*/
ods select none ;
ods output  SurvivalPlot= SurvivalPlot ;
proc lifetest data=sashelp.bmt  plots=survival(cl atrisk=(0 to 2500 by 500) ) ; 
time T*Status(0);
Strata Group;
run;
ods select all ;

data SurvivalPlot1;
 merge SurvivalPlot SurvivalPlot(keep=StratumNum Time 
 rename=(StratumNum=_StratumNum Time=_Time) firstobs=2);
output;
if StratumNum=_StratumNum  then do;
 do Time=Time+1 to _Time-1;
  call missing(Censored,AtRisk,tAtRisk);output;
 end;
end;
drop _StratumNum _Time;
run;
data SurvivalPlot2;
 set SurvivalPlot1;
 by StratumNum;
 retain new_SDF_UCL new_SDF_LCL new_Survival;
 if first.StratumNum then call missing(new_SDF_UCL,new_SDF_LCL,new_Survival);
 if not missing(SDF_UCL) then  new_SDF_UCL=SDF_UCL;
 if not missing(SDF_LCL) then  new_SDF_LCL=SDF_LCL;
 if not missing(Survival) then  new_Survival=Survival;
 Stratum=scan(Stratum,-1,':');
run;
proc sgplot data=SurvivalPlot2;
where Time>=500 ;   /* <------- Here is */
band x=Time lower=new_SDF_LCL  upper=new_SDF_UCL /group=Stratum transparency=0.8 ;
step x=Time y=new_Survival /group=Stratum name='a';
scatter x=Time y=Censored/group=Stratum markerattrs=(symbol=plus);
xaxistable AtRisk/ x=tAtRisk class=Stratum colorgroup=Stratum location=inside  
                   TITLEATTRS=(size=8 weight=bold) VALUEATTRS=(size=8 weight=bold);
inset '+ Censored' /position=ne border;
keylegend 'a'/title='Disease Group';
yaxis values=(0 to 1 by 0.2);
run;

If you remove "where Time>=500 ; " ,you could get this :

[Ksharp · Accepted solution]

/*
Here could get more simple code,
I missed an important option TYPE=STEP
*/
ods select none ;
ods output  SurvivalPlot= SurvivalPlot ;
proc lifetest data=sashelp.bmt  plots=survival(cl atrisk=(0 to 2500 by 500) ) ; 
time T*Status(0);
Strata Group;
run;
ods select all ;



proc sgplot data=SurvivalPlot;
where Time>=500 ;   /* <------- Here is */
band x=Time lower=SDF_LCL  upper=SDF_UCL /group=Stratum transparency=0.8 type=step;
step x=Time y=Survival /group=Stratum name='a';
scatter x=Time y=Censored/group=Stratum markerattrs=(symbol=plus);
xaxistable AtRisk/ x=tAtRisk class=Stratum colorgroup=Stratum location=inside  
                   TITLEATTRS=(size=8 weight=bold) VALUEATTRS=(size=8 weight=bold);
inset '+ Censored' /position=ne border;
keylegend 'a'/title='Disease Group';
yaxis values=(0 to 1 by 0.2);
run;

[Medidata]

Thank you, It's worked....