replace every nth word with a nth word concatenated with a symbol

[Jagadishkatam]

Dear Expert,

Could you please help me concatenate every nth word with a symbol.

Consider that i have a string data like below

"having a common variable to merge by ensures that the"

the expected output should be

"having a common * variable to merge * by ensures that * the"

So after every 3rd word i have to place the symbol(*). like above.

Could you please suggest a solution.

Thanks,

Jag

[PGStats · Accepted solution]

Put the CATx functions to good use:

data test;
length subStr outStr $200;
inStr = "having a common variable to merge by ensures that the";
do i = 1 by 3 until(Missing(subStr));
    subStr = catx(" ", scan(inStr,i), scan(inStr,i+1), scan(inStr,i+2));
    outStr = catx(" * ", outStr, subStr);
    end;
drop subStr i;
run;

proc print data=test noobs; run;

[Jagadishkatam]

Thank you so much PG , it worked

[Haikuo]

Here is another way:

data test;
length outStr $200;
inStr = "having a common variable to merge by ensures that the";
outstr=prxchange('s/((\w+ ){3})/$1* /', -1, instr);
run;

This is to tell SAS adding * right after the 3rd word, in a literal sense. 

[Jagadishkatam]

Thank you Haikuo it was wonderful.