removing all the variables without any observations from my dataset

[Emma_at_SAS]

I am checking the variables with missing observations in my dataset (using the code below). Now, I want to remove the variables that contain no observations from my dataset. I think about 10% of my variables are all missing observations. My sample size is 2100 and I have 1500 variables. I appreciate your suggestions. Thanks  

data count_missing; set &dataset; run;

proc format;
 value $missfmt ' '='Missing' other='Not Missing';
 value  missfmt  . ='Missing' other='Not Missing';
run;
 
proc freq data=count_missing; 
format _CHAR_ $missfmt.; /* apply format for the duration of this PROC */
tables _CHAR_ / missing missprint nocum nopercent;
format _NUMERIC_ missfmt.;
tables _NUMERIC_ / missing missprint nocum nopercent;
run;

[PaigeMiller · Accepted solution]

Example using SASHELP.ZIPMIL (which has lots of missings), using the NLEVELS option of PROC FREQ

ods output nlevels=nlevels;
proc freq data=sashelp.zipmil nlevels; 
format _CHAR_ $missfmt.; /* apply format for the duration of this PROC */
tables _CHAR_ / missing missprint nocum nopercent;
format _NUMERIC_ missfmt.;
tables _NUMERIC_ / missing missprint nocum nopercent;
run;

proc sql noprint;
    select tablevar into :varnames separated by ' ' from nlevels where nnonmisslevels=0;
quit;

data want;
    set sashelp.zipmil(drop=&varnames);
run;

[Emma_at_SAS]

Thank you, PaigeMiller. It works very well!

[PaigeMiller]

Also, your formats are not needed, even though I left them in the code.

[sbxkoenk]

Hello,

I advise you to search the SAS-communities first to find your answer (before asking your question).

It may save you some valuable time!

This question, for example, is posted rather frequently.

See for example:

Deleting Variables with Only Missing Values from Dataset with 4000+ Variables

https://communities.sas.com/t5/New-SAS-User/Deleting-Variables-with-Only-Missing-Values-from-Dataset...

You will find multiple solutions there.

Koen

[Emma_at_SAS]

Hi Koen,
Thank you, for your advice. Next time, I will search the previous posts more carefully.
Thanks,
Mary

[Ksharp]

https://www.sas.com/content/dam/SAS/support/en/sas-global-forum-proceedings/2020/4737-2020.pdf

[Emma_at_SAS]

Great, thank you, Ksharp!