remove observation with missing value

[ysmnkmlia]

Hi, i have a dataset of pisa2022 and i need to filter out observation with missing value at any variable. The solution is preferably to be in the data step. Is there anyone with an idea to solve this?

Below is my data step before removing the observation with missing value

data work.Project_pisa2022;
set pisa2022.Project_pisa2022;
keep CNT ST004D01T PV1MATH PV2MATH PV3MATH PV4MATH PV5MATH PV6MATH PV7MATH PV8MATH PV9MATH PV10MATH
PV1READ PV2READ PV3READ PV4READ PV5READ PV6READ PV7READ PV8READ PV9READ PV10READ
PV1SCIE PV2SCIE PV3SCIE PV4SCIE PV5SCIE PV6SCIE PV7SCIE PV8SCIE PV9SCIE PV10SCIE;
where CNT in('MYS', 'SGP', 'CHE');

run;

[Patrick]

Something along the line of below should work for you.

data work.have;
  set sashelp.class;
  if _n_=5 then call missing(name,age);
  if _n_=8 then call missing(height);
run;

proc sql noprint;
  select name into :varlist separated by ','
  from dictionary.columns
  where libname='WORK' and memname='HAVE'
  ;
quit;

data work.want;
  set have;
  if cmiss(&varlist)>0 then delete;
run;

proc print data=work.want;
run;

[FreelanceReinh]

Hi @ysmnkmlia and welcome to the SAS Support Communities!

Similar to Patrick's solution, you can also replace the KEEP statement with a KEEP= dataset option and then apply the CMISS function to the _ALL_ variable list:

data work.Project_pisa2022;
set pisa2022.Project_pisa2022(keep=CNT ST004D01T
  PV1MATH PV2MATH PV3MATH PV4MATH PV5MATH PV6MATH PV7MATH PV8MATH PV9MATH PV10MATH
  PV1READ PV2READ PV3READ PV4READ PV5READ PV6READ PV7READ PV8READ PV9READ PV10READ
  PV1SCIE PV2SCIE PV3SCIE PV4SCIE PV5SCIE PV6SCIE PV7SCIE PV8SCIE PV9SCIE PV10SCIE);
where CNT in('MYS', 'SGP', 'CHE');
if cmiss(of _all_)=0;
run;