@imdickson
I truly understand about the learn from basics part. Currently i will have to settle my works on my hand first.
Actually, I believe you haven't understood what we're trying to tell you. If you got lost in your code then DO NOT TRY TO FIX EVERYTHING AT ONCE. Take a step back!
You've got now a macro with lots of code in it and it's not working. One way to go:
1. Create a backup of your current code.
2. Start a new code (a brand new .sas file or EG/Studio code node).
3. Copy the macro "shell" to your new code: %macro blah(...); %mend; %blah(...) - run it. If no error then proceed else debug and fix.
4. Copy the very first run group from your backed up code into the new code (ie. the first proc sql, data step etc.). If you've got already macro syntax in this first step: Remove it as far as possible - run it. If no error then proceed else debug and fix.
5. If there had been macro syntax/logic: add it back - run it. If no error then proceed else debug and fix.
6. Now add the next logical unit ....and so on and so on, step by step
For your latest question: I don't believe you need these quotes.
The way SAS Macro code interacts with "normal" SAS code:
First comes the SAS Macro guy (could also be a girl of course). This one looks all the code and searches for % and & - these are the tokens for the SAS Macro guy telling him that this is his job and he needs to do something with it. The SAS macro guy consumes everything macro and once he's done only non macro stuff remains.
Now comes the SAS girl. She picks up the "left overs" and does then does her thing with it, i.e. executes the "left over" Proc SQL syntax.
If you're using options mprint and mlogic for the code I've posted earlier then the log shows you what the macro guy does and what the SAS girl has to do.
options mprint mlogic;
/* macro definition */
%macro test(selected_var);
proc sql feedback;
select
name,
age,
case
%if %upcase(&selected_var) = USE_HEIGHT %then
%do;
WHEN height<60 THEN 'Height <60'
ELSE 'Height >=60'
%end;
%else %if %upcase(&selected_var) = USE_WEIGHT %then
%do;
WHEN weight<90 THEN 'Weight <90'
ELSE 'Weight >=90'
%end;
end as
my_selected_var length=20
from sashelp.class
;
quit;
%mend;
/* macro call */
%test(use_weight)
The macro call generates the following log:
54 /* macro call */
55 %test(use_weight)
MLOGIC(TEST): Beginning execution.
MLOGIC(TEST): Parameter SELECTED_VAR has value use_weight
2 The SAS System 16:02 Wednesday, July 19, 2017
MPRINT(TEST): proc sql feedback;
MLOGIC(TEST): %IF condition %upcase(&selected_var) = USE_HEIGHT is FALSE
MLOGIC(TEST): %IF condition %upcase(&selected_var) = USE_WEIGHT is TRUE
MPRINT(TEST): select name, age, case WHEN weight<90 THEN 'Weight <90' ELSE 'Weight >=90' end as my_selected_var length=20 from
sashelp.class ;
NOTE: Statement transforms to:
select CLASS.Name, CLASS.Age, case
when CLASS.Weight < 90 then 'Weight <90'
else 'Weight >=90'
end as my_selected_var length=20
from SASHELP.CLASS;
MPRINT(TEST): quit;
NOTE: The PROCEDURE SQL printed page 1.
NOTE: PROCEDURE SQL used (Total process time):
real time 0.01 seconds
cpu time 0.03 seconds
MLOGIC(TEST): Ending execution.
What's shown in lines starting with MLOGIC is what the Macro guy has been doing, what's shown in lines starting with MPRINT is what the macro guy left over for the SAS girl to do; and the rest of the log shows you what the SAS girl has been doing.
And the sometimes a bit fiddely thing with macro coding: You must code carefully so that the macro guy only leaves stuff behind for the SAS girl which is really hers to deal with - this one is not very generous in this regards and throws errors if not treated with respect.
