proc tabulate dummy variable

[archibald]

Hi all, I have 5 dummy variables coded 1- Yes 0-No

Is there a way proc to tabulate dummy variables just to display the" Yes" categories   and also the total (sum of  both yes and No) for for each variable.

Thank You.

[Reeza]

No. But if it's coded as 0/1 perhaps you can use proc means to get the summary you want? 

N = count of obs

Sum = num yes

Mean = percent of yes

[Ksharp]

proc format;
value $fmt(multilabel)
 'F'='F'
 'F','M'='ALL';
run;

proc tabulate data=sashelp.class;
class sex/mlf ;
format sex $fmt.;
table sex*n='';
run;

[data_null__]

data class;
   set sashelp.class;
   sexdummy = sex eq 'F';
   sexdumm2 = sexdummy;
   run;
proc tabulate;
   var sexdummy sexdumm2;
   tables (sexdummy sexdumm2)*(sum='Count'*f=f8. n='Denom'*f=f8. mean='Percent'*f=percentn.);
   label sexdummy='Gender';
   run;

[ballardw]

Provide some example data and what you want the result to look like.

When you say " and also the total (sum of  both yes and No) for for each variable" for a variable coded 1/0 then all of the 0's always sum to 0 so there is likely some additional details that you are leaving out. I suspect you have some nesting levels that you are not specifying clearly.