proc sql help for counting Number of subjects

[knveraraju91]

Dear,

I am trying to calculate number of subjects for dose and Total number in my data. I got the values i need in my output except for "Total " variable. In the program below, there are 6 distinct subjects in the data. But I am getting 8 for total value. Please help in my code to get 6 for 'Total' variable.

Thank you

data one;
input id term$ dose$;
datalines;
1 hache 10mg
1 sache 20mg
2 epain 20mg
2 lpain 10mg
3 rash placebo
4 coli 40mg
5 capin 40mg
6 naus 40mg
6 vomit 20mg
;

proc sql;
create table two as
select count(distinct ID) as NS,dose
from one
where dose in ('10mg' '20mg' '40mg' 'placebo')
group by dose;
quit; 

proc transpose data=two out=three(drop=_NAME_);
  var NS;
  id dose;
run;

data four;
  set three;
  array data  _10mg _20mg _40mg placebo;
  do over data;
    if missing(data) then data=0;
  end;
  TOTAL=_10mg + _20mg + _40mg ;
run;

[mkeintz]

You've made a good case for the UNION operator in SQL (assuming you must  use SQL).

proc sql;

  create table two as

   select count(distinct ID) as NS,dose

   from one

   where dose in ('10mg' '20mg' '40mg' 'placebo')

   group by dose

 union

   select count(distinct ID) as NS, 'TOTAL' as dose

   from one

  ;

quit;

proc transpose data=two out=three(drop=_NAME_);

var NS;

id dose;

run;

Also you don't need to follow the proc transpose with a data step.

[Reeza]

If you're using a report procedure to summarize, it can add the total.