multiple paired test

[yoyong]

Hi.

I want to do a paired test. I have a set of pre scores and two sets of post scores. 

For example:

Pre-exercise            Postexercise1       Postexercise2

12                                       21                       26

15                                       15                       16

18                                       18                       18

25                                       30                       28

25                                       25                       27                 

How do I do it in SAS without doing paired t-tests four times?

Thanks in advance.

[PGStats]

You can do all comparisons in a single run of proc ttest

data have;
input Pre Post1 Post2;
datalines;
12                                       21                       26
15                                       15                       16
18                                       18                       18
25                                       30                       28
25                                       25                       27
;

proc ttest data=have;
paired Pre:Post1 Pre:Post2 Post1:Post2;
run;

[PGStats]

But if you want all tests to be based on the same error variance estimate, you can do

data have;
input Pre Post1 Post2;
datalines;
12                                       21                       26
15                                       15                       16
18                                       18                       18
25                                       30                       28
25                                       25                       27
;

data test;
set have;
length test $5;
subj + 1;
test = "Pre"; value = Pre; output;
test = "Post1"; value = Post1; output;
test = "Post2"; value = Post2; output;
keep subj test value; 
run;

proc glm data=test;
class subj test;
model value = subj test;
lsmeans test / pdiff;
run;