You need to explain WHY you want to do this to get a better solution to your actual problem.
But in the meantime let's look at the difficulties of trying to do what you want.
First it is extremely hard to embed a line of data into a program and not have it get mangled by the editor (either the program or the human editor). Especially if you want to embed a line that is over 400 characters long.
Second it is even harder to do that with a %LET statement.
It is easier to enter the text as a string in a program. That will help a little since it is not as easy for the SAS parse to mess up the string if it is properly quotes. Although it would still be easy for editor(s) to mess up the content, especially with such a really long line with so many spaces.
So something like this.
filename mydata temp;
data _null_;
file mydata ;
put ' 0000001 11CA001CA0CAUSCA0010600031CA57750184NYUSNY 410102F1091 442411 1W609221911012020042003U UND 1 K743300 095 3090311R092 21J189 61K743 03 J189 K743 R092 101 11100 100 6YNNNNNNNNNNNNNN NNNN 05';
run;
If you did already have the value in a macro variable then you could replace the string literal in the PUT statement with a reference to the macro variable.
put "&sc";
Then your program just needs to read from the temp file your data _null_ step created.
You should simplify your INPUT statement to make it more readable (and hence more maintainable).
data rawread;
infile mydata;
input
id $ 4-9
loc1 $ 21-22
loc2 $ 29-30
xxm $ 146-149
trr 163-164
@165 (x1-x20) ($7.)
y 341-342
@344 (m1-m20) ($5.)
;
run;
It it even easier if the data is already in a dataset. But in that case just keep it in the dataset and don't convert it to either text or macro variable. Let's say you have the data in a variable called LINE in a dataset called RAWDATA. Then you can use the following _INFILE_ "trick" to use the INPUT statement to read from the line of data.
filename dummy temp;
data _null_;
file dummy;
put 'This will be ignored';
run;
data rawread;
set rawdata ;
infile dummy lrecl=2000 truncover ;
input @ ;
_infile_ = line ;
input
id $ 4-9
loc1 $ 21-22
loc2 $ 29-30
xxm $ 146-149
trr 163-164
@165 (x1-x20) ($7.)
y 341-342
@344 (m1-m20) ($5.)
@1 @@
;
run;
