how to read latest csv file from a directory present in unix using sas code

[Sandhya55]

how to read latest csv file from a directory present in unix using sas code

[PaigeMiller]

I think this might be the answer

https://communities.sas.com/t5/SAS-Programming/Reading-filenames-date-and-time-from-a-directory/m-p/...

[Kurt_Bremser]

Latest by modification timestamp, or by a timestamp coded into the filename?

[Sandhya55]

i have used below script to get the latest csv file in directory :

but the script is not working for me .can any one please help me resolve the issue.

filename file1 pipe "cd /folder/sub-folder ;ls -t | head -1" ;
libname file_ext 'cd /folder/sub-folder/file_ext' ;

data file_ext.file2_Read ;

infile file1 truncover ;
input filename $100 ;
put filename=;
/*
call symputx('lastfile',file1);
*/
run;

[Kurt_Bremser]

Please answer my question.

[Sandhya55]

Latest by modification timestamp

[Kurt_Bremser]

Your LIBNAME won't work; you can't use a UNIX command as a path

Simplify your code first to see if you get the desired file.

filename file1 pipe "cd /folder/sub-folder ;ls -t | head -1" ;

data _null_;
infile file1 truncover ;
input filename $100.;
put filename=;
run;

Read the log to see the filename; if you have issues, please copy/paste your log into a window opened with this button:

[Sandhya55]

Thanks !!! latest file name is listed in filename .Can you please provide the syntax to read this file as we are dynamically getting the file name from directory

[Kurt_Bremser · Accepted solution]

First, replace the PUT with the CALL SYMPUTX:

filename file1 pipe "cd /folder/sub-folder ;ls -t | head -1" ;

data _null_;
infile file1 truncover ;
input filename $100.;
call symputx('fname',filename);
run;

Then, define the target library, andv' read the file into a dataset:

libname file_ext '/folder/sub-folder/file_ext' ;

data file_ext.file2_Read ;
infile "/folder/sub-folder/&fname." dlm="," dsd truncover;
input
  /* insert variables to be read */
;
run;

[Kurt_Bremser]

You could further simplify the retrieval of the filename:

data _null_;
infile "ls -t /folder/subfolder/*.csv" pipe truncover ;
input filename $200.;
call symputx('fname',filename);
stop;
run;

The macro variable should have the complete path in it, so you don't need to explicitly code it in the next data step.