flagging based on a different datset

[Melk]

I have 2 datasets, data1 is repeated and data2 is not. I would like to add a flag=1 in data1 if ID is in data2 and flag=0 if not. I have the following code but it is marking all as flag=0, can you please help me troubleshoot?

   
data dataflagged;
  if _N_ = 1 then do;  
    declare hash CHK(dataset: "data2", multidata:'y');
    CHK.definekey("ID");
    CHK.definedone();
  end;
  set data1;
  flag = (CHK.check()=1);
run;
quit;

[ChrisNZ]

If found, CHK.check()=0.

[PGStats]

data dataflagged;
  if _N_ = 1 then do;  
    declare hash CHK(dataset: "data2");
    CHK.definekey("ID");
    CHK.definedone();
  end;
  set data1;
  flag = CHK.check() = 0;
run;

[Melk]

It is marking all flags as 0 for some reason. The ID variable are numbers formatted as 8.characters. in both datasets. I am just eyeballing and I see a lot of matching IDs, so I cant figure out why the flag isnt working..

[PGStats]

Are they really equal in both datasets, or just equal once formatted?

[Melk]

Not sure I know the difference but they are equal in values before and after formatting.

[PGStats]

It *should* work.

data data1;
do id = 1,1,2,7,9; output; end;
format id 8.;
run;

data data2;
do id = 1,7; output; end;
format id 8.;
run;

data dataflagged;
  if _N_ = 1 then do;  
    declare hash CHK(dataset: "data2");
    CHK.definekey("ID");
    CHK.definedone();
  end;
  set data1;
  flag = CHK.check() = 0;
run;

proc print noobs; run;

                                        id    flag

                                         1      1
                                         1      1
                                         2      0
                                         7      1
                                         9      0

Post the actual code you are using.

[Melk]

it seems the ID needs to be numeric for it to work. ID as character did not work for me.

[PGStats]

This works:

data data1;
do id = "1","1","2","7","9"; output; end;
run;

data data2;
do id = "1","7"; output; end;
run;

data dataflagged;
  if _N_ = 1 then do;  
    declare hash CHK(dataset: "data2");
    CHK.definekey("ID");
    CHK.definedone();
  end;
  set data1;
  flag = CHK.check() = 0;
run;

proc print noobs; run;

                                                       id    flag

                                                       1       1
                                                       1       1
                                                       2       0
                                                       7       1
                                                       9       0