calculating difference from previous observation by 2 variables

[Melk]

I am trying to calculate the difference of a variable Y from the previous visit by subject and by limb.

Sample data:

Y     ID    Limb   Visit

1      1      R        1

3      1      R        2

4      1      R        3

5      1      L        1

5      1      L        2

3      1      L        3

2      2      R        1

3      2      R        2

4      2      R        3

4      2      L        1

7      2      L        2

1      2      L        3

I am using this code:

proc sort data=dat; by id limb visit;
run;

data dat;
    set dat;
    by id limb;
    retain r_days;
    r_days = lag(age);
    if not first.id then do;
        days = age - r_days;
    end;
    drop r_days;
run;

But it is not doing this by LIMB, only by ID. Cant figure out what is wrong with my code.

[Reeza · Accepted solution]

 if not first.id <- change this to limb, not ID. Your FIRST. should be at the lowest level you're looking to analyze.

[Melk]

That was simple- thanks!

[ballardw]

Since your example data doesn't include AGE (hint) as a variable and you don't show an expected result (hint) this is a stab at an alternate approach.

data dat;
    set dat;
    by id limb;
    days=dif(age);
    if first.limb then days=.;
run;

People often forget there is a complementary function that behaves similar to LAG called DIF that does the calculation you are looking for.

I am not sure why you think you need to retain r_days as you never use the value from the previous record.

Of course you may have actually want to calculate the cumulative days from the first value of limb which would look more like

data dat;
   set dat;
   by id limb;
   retain r_days;
   if first.limb then r_days=age;
   else days= age-r_days;
   drop r_days;
run;