In my experience using Excel as the source for "code injection" and parameter driven generation of dynamic code, is not a good approach. Having said that, I had lately to implement something similar for a very special use case.
I would go for a 2 step approach.
1. Load your data from Excel into a permanent SAS table. This process should also do some syntax validation. You could for example generate a data _null_ step and execute all your code in there. Only load the new data into the permanent parameter table if this data _null_ step executes without any errors.
2. Generate your dynamic code using the permanent SAS table. Below a code sample which might get you started.
/* excel data loaded into SAS work table */
data excel_source;
infile datalines4 truncover dlm=',' dsd ;
input table:$41. variable:$32. code:$200.;
datalines4;
sashelp.class,age,if age<15 then age=10; else age=20;
sashelp.othertable,age,if age=99
sashelp.class,sex,if sex='M' then sex='m';
;;;;
run;
/* syntax check source data */
filename codechk temp;
data _null_;
file codechk;
set excel_source end=last;
if _n_=1 then put 'data _null_;';
put @3 code;
if last then put 'run;';
run;
%include codechk /source2;
/* only load parameter table if there is no error */
data param;
set excel_source;
run;
/* sample for dynamic code */
filename codegen temp;
data _null_;
file codegen;
set param(where=(upcase(table)=upcase("SASHELP.CLASS"))) end=last;
if _n_=1 then
do;
put
'data want;'
/ ' set ' table ';'
;
end;
put @3 code;
if last then
do;
put 'run;';
end;
run;
%include codegen /source2;
...but again: I'd consider such an approach only as the right thing to do in very rare and "exotic" circumstances. What's your use case for this?
