Writing to an external file with a delimiter

[sfffdg]

Hi 

when i tried to write data to an external file with a delimiter,it is writing data to the file but with no delimiter.

The code is as below

data _null_;
file " &ctl_file " dlm='|' ;
put "&business_dt_tm" "&business_dt_tm" "&extract_dt_tm" "&extract_dt_tm" "&rec_count" "&sequencenum";
run;

What's wrong with the code?

Thanks,

Swathi

[ChrisNZ]

You are writing text, not data, So the text is written as is.

data _null_;
file " &ctl_file " dlm='|' ;
put VAR1 VAR2 ;
run;

will use the delimiter

[Tom · Accepted solution]

The PUT statement will not write delimiters between string literals.  Either include the delimiter in the strings,

data _null_;
  file "&ctl_file" dsd dlm='|' ;
  put "&business_dt_tm|&business_dt_tm|&extract_dt_tm" 
       "|&extract_dt_tm|&rec_count|&sequencenum"
  ;
run;

or put the strings into a variable and write the variable.

data _null_;
  file "&ctl_file" dsd dlm='|' ;
  length name $100 ;
  do name = "&business_dt_tm" ,"&business_dt_tm", "&extract_dt_tm" 
           ,"&extract_dt_tm", "&rec_count", "&sequencenum"
  ;
    put name @ ;
  end;
  put;
run;

Also don't put spaces at the beginning and end of your filenames. You will have a real hard time referencing those files again!

[sfffdg]

Thank you Sir!!