Why proc print made error?

[randomman]

data a;
input name $ age height weight;
datalines;
don 28 168 76
;run;
%macro cols1; name age; %mend;
%macro cols2; height weight; %mend;
proc print data = a; var %cols2 %cols1; run;

[Astounding · Accepted solution]

Calling %cols2 generates all the text within the macro:

height weight;

Extrapolating upon this, your full VAR statement generates:

var height weight; name age;

Clearly, there's an extra semicolon. A good solution would be to remove the generated semicolons from the macro definition. Have %cols2 generate only:

height weight

Then add a semicolon for the VAR statement when calling the macros:

var %cols2 %cols1 ;

[Patrick]

Remove the semicolons and your code will work.

You normally only use macros for dynamic code generation. 

For your case you'd rather use macro variables as in below sample code.

%let cols1=name age;
%let cols2=height weight;

proc print data = a;
  var &cols2 &cols1;
run;

 A macro definition for your sample could look like:

%macro doit(cols1,cols2);
  proc print data = a;
    var &cols2 &cols1;
  run;
%mend;

%doit(name age, height weight);

And as an advice: Don't dive too early into SAS macro coding. First get "solid" with SAS data step and SAS Proc's.